.include "m8def.inc"	;AT8-16, кварц4МГц, угол 30


.org 0				;начало кода
	rjmp start
.org 1				;нога int0
	rjmp datchik1
.org 2				;нога int1
	rjmp datchik2
.org 6				;Output Compare1A Interrupt Vector Address
	rjmp timer1compare
.org 8				;переполнение timer1
	rjmp timer1
.org 14				;прер. АЦП
	rjmp adc_complete;подпрограмма АЦП (срабатывает редко)


start:
;=========Стек===========
ldi R16, low(RAMEND) ;низ стека
out SPL, R16 
ldi R16, high(RAMEND);верх стека
out SPH, R16
;====установка портов====
ldi R16, 0b00000011
out ddrC, R16		;PС
ldi R16, 0b11111100
out PortC, R16		;подтягивающие резисторы
ldi R16, 0b11010010
out ddrD, R16		;PD0-RXD;PD1-TXD;PD2,PD3-signal;PD6-stopDC
ldi R16, 0b00101101
out PortD, R16		;подтягивающие резиторы
ldi R16, 0b00000111     ;pb0-искра,pb1-тиристор
out ddrB, R16		;PB
ldi R16, 0b11111000
out PortB, R16		;подтягивающие резисторы
;========регистры========
clr R0				;для умножения
clr R1				;для умножения
clr R2				;"0",для умножения
clr R3                          ;stab
clr R4                          ;stab
clr R5			;старший бит задержки x%
clr R6			;младший бит задержки x%
clr R7				;OCR1AH
clr R8				;OCR1AL,искра
clr R9				;TCNT1H
clr R10				;TCNT1L,счет1
clr R11				;TCNT1H
clr R12				;TCNT1L,счет2
ldi R16,8
mov R14,R16			;АЦП,на старте среднее
clr R15				;рон sreg,счетч
clr R16
clr R17
clr R18				;задержка опускания искры
clr R19				;упр.DC-CDI	 
ldi R20,0b10000000	;РОН статуса
clr R21				;РОН рассчета задержки для ОЗУ
clr R22				;изменение длительности импульса
ldi R23,36			;длинна метки,х0.7°,160=112°
clr R24				;множитель импульс выкл тиристора
clr R25				;множитель задержки из ОЗУ
clr R26				;РОН "lowX",адресация ОЗУ,LD
clr R27				;POH "highX",адресация ОЗУ,LD
clr R28				;растяжка ослепления
clr R29				;задержка "ослепления"
clr R30
;===таблица в озу===
rcall FuozTable1
rcall FuozTable2
rcall FuozTable3	;таблицы задержек в ОЗУ

;========Timer=======
ldi R16, 0b00000010	;задержка 8,для счета при 4МГц
out TCCR1B, R16 	;пуск таймера 16-бит
ldi R16, 0b00010100
out TIMSK, R16 		;настройки 16-бит счетчика
;=========АЦП========
ldi R16, 0b01100010	;AD_Converter ADMUX byte
out ADMUX, R16
ldi R16, 0b10001101	;AD_Converter ADCSRA byte,125kHz
out ADCSRA, R16		;первый замер АЦП 800т,следующие 416т
;===прерывания ног===
ldi R16, 0b11000000
out GICR, R16		;вкл.прерывания по int0,int1
ldi R16, 0b00001010
out MCUCR, R16		;прерывание по падающему фронту
sei 				;вкл. прерывания в ЦП
;==конец инициализации устройств, далее основной код==
//////////////////////////////////////////////////////////
;таблица контрольных бит,РОН20
;R20/7-холостые обороты,переполнение 16-бит счетчика
;R20/6-запрет обработки импульса,"ослепление" входа
;R20/5-обработан импульс датчика1,счет математики разрешен
;R20/4-расчет искры завершен,вкл.сравнение счетчика
;R20/3-переход на "предсказание" оборота 0x1FF
;R20/2-обработан импульс датчика2,счет математики разрешен
;R20/1-АЦП,коректор,замер сделан
//////////////////////////////////////////////////////////

main:
;блок задержки искры, опускает искру(6mks/1)
;не отнимая сремени ЦП на выполнение кода
sbic PinB,0	;выполнить если бит порта "1"
inc R18		;+1
cpi R18, 40	;200mks
brlo main2	;перейти если меньше -откл искру
cbi PortB,0	;лог"0"на выход "искра"
clr R18		;РОН задержки опускания искры
sbi ADCSRA,6	;старт замер АЦП
main2:

;блок flyback
;не отнимая сремени ЦП на выполнение кода
sbic PinD,6		;выполнить если бит порта "1"
inc R19			;+1
cp R19,R22	;252mks
brlo main3	;перейти если меньше
clr R19
inc R28         ;длительность отключения зависит от оборотов
cpi R28,10
brlo main3      ;а если больше,вкл.вход
clr R19		;РОН задержки DC-CDI
clr R28
cpi R21,204     ;сравнение оборота выше 2300
brsh main3      ;если меньше 2300 вкл DC
cbi PortD,6	;pd6=0 вкл DC
main3:


;болок "ослепления" входа датчика
sbrc R20, 6		;if pinX,n='1' then do
inc R29			;+1
cpi R29, 250		;120mks,ослепление
brlo main4
cbi PortD,4
andi R20, 0b10111111;cbiR20/6, контроль
clr R29			;обнуляем переменную
main4:

;блок управления зарядом (тиристором)
sbic PinB,1      ;если тиристор закрыт
inc R24
cpi R24, 50      ;пауза 250мкс
brlo main5              ;
cbi PortB,1      ;pb1=0 включаем тиристор для заряда 
clr R24
main5:

sbrs R20, 5		;if pinX,n='0' then do
rjmp main
sbrc R20, 7		;if pinX,n='1' then do
rcall holostie	;сюда,если обороты ниже 460/мин
rcall norm		;счет математики,импульс1
rjmp main
nop
nop
nop
;-------------------------------------------------------------
;----------------далее только подпрограммы--------------------
;-------------------------------------------------------------
;==переполнение 16-бит счетчика==
timer1:
;переполнение означает что частота оборотов ниже 480/мин
in R15,SREG		;сохраним SREG
ori R20, 0b10000000	;sbiR20/7, контроль
out SREG,R15	;восстановим SREG
reti


;=совпадение сравнения OCR1A, 16-бит счетчика=
;рассчетная искра цилиндра один
timer1compare:
in R15,SREG		;сохраним SREG
sbrs R20, 4		;if pinX,n='0' then do
reti
ori R20, 0b01000000	;sbiR20/6,ослепление
sbi PortD,4
sbi PortB,0		;лог"1"на выход "искра"
cpi R21,204	     ;сравнение
brsh odin1	     ;если обороты меньше 2300
sbi PortB,1          ;закрываем тиристор -будет много искр
odin1:
andi R20, 0b11101111;cbiR20/4,искра
out SREG,R15	;восстановим SREG
reti


;===первый сигнал датчика===
datchik1:
in R15,SREG		;сохраним SREG
sbic PinD,4	;выполнить если бит порта "1"
rjmp d1propusk	;ошибка,вых.
sbi PortD,6		;лог"1"на выход "flyback"
in R10, TCNT1L
in R9, TCNT1H	;считываем показания счетчика
out TCNT1H, R2	;R2=0
out TCNT1L, R2	;обнуляем счетчик
ori R20, 0b00100000	;sbiR20/5, контроль
sbi PortD,4
;показания счетчика записаны, счетчик обнулен
;контрольный бит расчета по первому сигналу
d1propusk:
out SREG,R15	;восстановим SREG
reti

;===второй сигнал датчика===
datchik2:
in R15,SREG		;сохраним SREG
sbrc R20, 6		;if pinX,n='1' then do
rjmp d2propusk	;ошибка,вых.
in R12, TCNT1L
in R11, TCNT1H	;считываем показания счетчика
ori R20, 0b00000100	;sbiR20/2,контроль
;показания счетчика записаны,контрольный бит
;готовности расчета по второму сигналу
d2propusk:
out SREG,R15	;восстановим SREG
reti


;====АЦП замер сделан====
adc_complete:
in R14, ADCL	
in R14, ADCH
lsr R14			;1/2=128
lsr R14			;1/2=64
lsr R14			;1/2=32
lsr R14
ori R20, 0b00000010;sbiR20/1,АЦП,контроль
reti


;====нормальные обороты=====
;=определяем задержку искры=
norm:
mov R21, R9		;скопируем значение счетчика 16-бит
com R21			;инвертируем число
;теперь имеем 255 значений счетчика оборотов,
;наименьшее значение - медленные обороты, большее - большые
;для усреднения точек таблицы выборка делаеться
;через некоторое число точек, для равномерности
ldi R22,250     ;число r22 зависит от оборотов
sub R22,R21     ;для растяжки импульса flyback
cpi R21, 236	;сравнение РОН с контстантой
brsh rpm19k5	;если больше или равно
cpi R21, 234	;сравнение РОН с контстантой
brsh rpm16k7	;если больше или равно
cpi R21, 232	;сравнение РОН с контстантой
brsh rpm14k6	;если больше или равно
cpi R21, 230	;сравнение РОН с контстантой
brsh rpm13k		;если больше или равно
cpi R21, 227	;сравнение РОН с контстантой
brsh rpm11k7	;если больше или равно
cpi R21, 225	;сравнение РОН с контстантой
brsh rpm10k6	;если больше или равно
cpi R21, 222	;сравнение РОН с контстантой
brsh rpm9k7		;если больше или равно
cpi R21, 218	;сравнение РОН с контстантой
brsh rpm9k		;если больше или равно
cpi R21, 216	;сравнение РОН с контстантой
brsh rpm8k3		;если больше или равно
cpi R21, 213	;сравнение РОН с контстантой
brsh rpm7k8		;если больше или равно
cpi R21, 210	;сравнение РОН с контстантой
brsh rpm7k3		;если больше или равно
cpi R21, 208	;сравнение РОН с контстантой
brsh rpm6k9		;если больше или равно
cpi R21, 206	;сравнение РОН с контстантой
brsh rpm6k5		;если больше или равно
cpi R21, 204	;сравнение РОН с контстантой
brsh rpm6k1		;если больше или равно
cpi R21, 202	;сравнение РОН с контстантой
brsh rpm5k6		;если больше или равно
cpi R21, 199	;сравнение РОН с контстантой
brsh rpm5k1		;если больше или равно
cpi R21, 196	;сравнение РОН с контстантой
brsh rpm4k7		;если больше или равно
cpi R21, 193	;сравнение РОН с контстантой
brsh rpm4k2		;если больше или равно
cpi R21, 190	;сравнение РОН с контстантой
brsh rpm3k9		;если больше или равно
cpi R21, 186	;сравнение РОН с контстантой
brsh rpm3k5		;если больше или равно
cpi R21, 182	;сравнение РОН с контстантой
brsh rpm3k		;если больше или равно
cpi R21, 177	;сравнение РОН с контстантой
brsh rpm2k8		;если больше или равно
cpi R21, 171	;сравнение РОН с контстантой
brsh rpm2k5		;если больше или равно
cpi R21, 165	;сравнение РОН с контстантой
brsh rpm2k2		;если больше или равно
cpi R21, 157	;сравнение РОН с контстантой
brsh rpm2k		;если больше или равно
cpi R21, 148	;сравнение РОН с контстантой
brsh rpm1k8		;если больше или равно
cpi R21, 138	;сравнение РОН с контстантой
brsh rpm1k5		;если больше или равно
cpi R21, 125	;сравнение РОН с контстантой
brsh rpm1k2		;если больше или равно
cpi R21, 109	;сравнение РОН с контстантой
brsh rpm1k		;если больше или равно
cpi R21, 88	;сравнение РОН с контстантой
brsh rpm0k8		;если больше или равно
cpi R21, 60	;сравнение РОН с контстантой
brsh rpm0k6		;если больше или равно
clr R26			;если 500 и меньше об/мин
rjmp RpmEnd		;всего 32строки
////////////////////////////////////////////////////////
rpm19k5:		;обороты
ldi R26, 0x1F	;задаем адрес ОЗУ "lowХ"
rjmp RpmEnd		;метка "дальше"
rpm16k7:
ldi R26, 0x1E
rjmp RpmEnd
rpm14k6:
ldi R26, 0x1D
rjmp RpmEnd
rpm13k:
ldi R26, 0x1C
rjmp RpmEnd
rpm11k7:
ldi R26, 0x1B
rjmp RpmEnd
rpm10k6:
ldi R26, 0x1A
rjmp RpmEnd
rpm9k7:
ldi R26, 0x19
rjmp RpmEnd
rpm9k:
ldi R26, 0x18
rjmp RpmEnd
rpm8k3:
ldi R26, 0x17
rjmp RpmEnd
rpm7k8:
ldi R26, 0x16
rjmp RpmEnd
rpm7k3:
ldi R26, 0x15
rjmp RpmEnd
rpm6k9:
ldi R26, 0x14
rjmp RpmEnd
rpm6k5:
ldi R26, 0x13
rjmp RpmEnd
rpm6k1:
ldi R26, 0x12
rjmp RpmEnd
rpm5k6:
ldi R26, 0x11
rjmp RpmEnd
rpm5k1:
ldi R26, 0x10
rjmp RpmEnd
rpm4k7:
ldi R26, 0x0F
rjmp RpmEnd
rpm4k2:
ldi R26, 0x0E
rjmp RpmEnd
rpm3k9:
ldi R26, 0x0D
rjmp RpmEnd
rpm3k5:
ldi R26, 0x0C
rjmp RpmEnd
rpm3k:
ldi R26, 0x0B
rjmp RpmEnd
rpm2k8:
ldi R26, 0x0A
rjmp RpmEnd
rpm2k5:
ldi R26, 0x09
rjmp RpmEnd
rpm2k2:
ldi R26, 0x08
rjmp RpmEnd
rpm2k:
ldi R26, 0x07
rjmp RpmEnd
rpm1k8:
ldi R26, 0x06
rjmp RpmEnd
rpm1k5:
ldi R26, 0x05
rjmp RpmEnd
rpm1k2:
ldi R26, 0x04
rjmp RpmEnd
rpm1k:
ldi R26, 0x03
rjmp RpmEnd
rpm0k8:
ldi R26, 0x02
rjmp RpmEnd
rpm0k6:
ldi R26, 0x01
;адрес ОЗУ "lowХ" определен
;задействованно ОЗУ 0х0100-0х011F,32строки
RpmEnd:

;выбор таблицы УОЗ тумблером на"0"
;приоритет у нижних таблиц
ldi R27, 0x01	;задаем "highX"таблица№1
sbis PinC,5		;выполнить если бит порта "0"
ldi R27, 0x02	;задаем "highX"таблица№2
sbis PinC,4		;выполнить если бит порта "0"
ldi R27, 0x03	;задаем "highX"таблица№3
;адрес ОЗУ "HighХ" определен, чтение ОЗУ
ld R25, X		;байт из ОЗУ-R27:26 загружается в РОН25


;АЦП корректор:
;sbi ADCSRA,6	;старт замер АЦП
sbrs R20, 1		;if pinX,n='0' then do
rjmp ADC_negotov
mov R17,R14		;новый сдвиг
andi R20, 0b11111101;cbiR20/1,контроль
ADC_negotov:
cpi R17,8		;средина резистора
brlo adc_plus	;если меньше
;adc_minus:
mov R16,R17
subi R16,8		;0...15
sub R25,R16		;"задержка" минус АЦП
brpl adc_exit	;если больше нуля,вых
clr R25			;иначе 0
rjmp adc_exit	;вых
adc_plus:
ldi R16,8
sub R16,R17		;инверсия,0...15
add R25,R16		;"задержка" плюс АЦП
adc_exit:

cpi R21, 172	 ;перейти если меньше 1400об
brlo troling     ;на стабилизацию оборотов
rjmp raschet
troling:
mov R6,R10	 ;копируем оборот
mov R5,R9		
cp R10,R4	 ;сравнимваем с предыдущим
cpc R9,R3		
breq rovno1	 ;если равны,нет рассчета
mov R10,R4      ;задержка будет по предыдущему обороту
mov R9,R3
rovno1:
mov R4,R6       ;запоминаем текущий оборот 
mov R3,R5       
;R10:R9-текуще-предыдущий для расчета.
;R4:R3-предыдущий
;R6:R5-текущий 

raschet:


;второй импульс датчика
cp R25,R23		;табл.с длинной метки
brlo pervii		;если табл.меньше,мат1
andi R20, 0b11111011;cbiR20/2,контроль
sbi PortB,2		;test led indicator
vtoroi:			;расчет по второму сигналу
sbrs R20, 2		;if pinX,n='0' then do
rjmp vtoroi		;ждем импульс
cp R25,R23		;если равны
brne noiskr
rjmp iskra		;искра без задержки
noiskr:			;иначе счет
sub R25,R23		;"табл."-"метка"
;далее расчет на "запаздывание",второй имп.дат.
mov R5,R9		;сохраним регистры
mov R6,R10		;счетчика
rcall matematika;R5R6*R25=R7R8
add R8,R12
adc R7,R11		;+счт.длина метки
;теперь имеем R7R8 значение задержки
;запишем в регистр сравнения счетчика
out OCR1AH, R7	;HighByte
out OCR1AL, R8	;LowByte
ori R20, 0b00010000	;sbiR20/4,контроль
andi R20, 0b11011011;cbiR20/52,контроль
ret

pervii:			;расчет по первому сигналу
cbi PortB,2		;test led indicator
;расчет на "запаздывание",первый имп.дат.
mov R5,R9		;сохраним регистры
mov R6,R10		;счетчика
rcall matematika;R5R6*R25=R7R8
;теперь имеем R7R8 значение задержки
;запишем в регистр сравнения счетчика цилиндра один
out OCR1AH, R7	;HighByte
out OCR1AL, R8	;LowByte
ori R20, 0b00010000	;sbiR20/4,контроль
andi R20, 0b11011111;cbiR20/5,контроль
ret


;подпрограмма умножения задержки
;R5R6*R25=R7R8
matematika:
lsr R5			;1/2,шаг смены
ror R6			;угла 360°/512=0.7°
mul R5,R25		;старший и младший
mov R8,R0
mov R7,R1
mul R6,R25		;младший и младший
add R8,R1
adc R7,R2		;R2=0
ret



;======искра без задержки, сразу по датчику=======
;при первом переходе с запаздывания на опережение
;этот блок нужен для устранения провала при переходе
iskra:
ori R20, 0b01000000	;sbiR20/6,ослепление
sbi PortD,4
sbi PortB,0		;лог"1"на выход "искра"
cpi R21,204	     ;сравнение
brsh odin2	     ;если обороты меньше 2300
sbi PortB,1          ;закрываем тиристор -будет много искр
odin2:
andi R20, 0b11011111;cbiR20/5,контроль
ret

;==холостые(низкие) обороты==
;режим активен при переполнении счетчика
;когда обороты ниже чем 460/мин
;при этом рассчет задержки невозможен
holostie:
ser R16			;РОН=0xFF
mov R9, R16		;сработает как 500/мин
mov R10, R16	;и мл.
andi R20, 0b01111111;cbiR20/7, контроль
ret


;==таблица №1,углов опережения в ОЗУ==
;=======для метки 20°, шаг 0.7°=======
FuozTable1:
ldi R27, 0x01	;задаем "highX"=01
ldi R26, 0x00	;задаем "lowX"=00
;опережение при оборотах
;500 и ниже, об/мин
ldi R16, 37	;множитель
st X+, R16	;в ОЗУ, 4,1°
;600 об/мин
ldi R16, 37	;множитель
st X+, R16	;в ОЗУ, 4,1°
;700 об/мин
ldi R16, 37	;множитель
st X+, R16	;в ОЗУ, 4,1°
;800 об/мин
ldi R16, 37	;множитель
st X+, R16	;в ОЗУ, 4,1°
;900 об/мин
ldi R16, 36	;множитель
st X+, R16	;в ОЗУ, 4,8°
;1000 об/мин
ldi R16, 36	;множитель
st X+, R16	;в ОЗУ, 4,8°
;1100 об/мин
ldi R16, 35	;множитель
st X+, R16	;в ОЗУ, 5,5°
;1200 об/мин
ldi R16, 34	;множитель
st X+, R16	;в ОЗУ, 6,2°
;1300 об/мин
ldi R16, 34	;множитель
st X+, R16	;в ОЗУ, 6,2°
;1400 об/мин
ldi R16, 33	;множитель
st X+, R16	;в ОЗУ, 6,9°
;1500 об/мин
ldi R16, 33	;множитель
st X+, R16	;в ОЗУ, 6,9°
;1600 об/мин
ldi R16, 32	;множитель
st X+, R16	;в ОЗУ, 7,6°
;1700 об/мин
ldi R16, 31	;множитель
st X+, R16	;в ОЗУ, 8,3°
;1800 об/мин
ldi R16, 30	;множитель
st X+, R16	;в ОЗУ, 9°
;1900 об/мин
ldi R16, 28	;множитель
st X+, R16	;в ОЗУ, 10,4°
;2000 об/мин
ldi R16, 26	;множитель
st X+, R16	;в ОЗУ, 11,8°
;2100 об/мин
ldi R16, 24	;множитель
st X+, R16	;в ОЗУ, 13,2°
;2200 об/мин
ldi R16, 22	;множитель
st X+, R16	;в ОЗУ, 14,6°
;2300 об/мин
ldi R16, 20	;множитель
st X+, R16	;в ОЗУ, 16°
;2400 об/мин
ldi R16, 18	;множитель
st X+, R16	;в ОЗУ, 17,4°
;2500 об/мин
ldi R16, 17	;множитель
st X+, R16	;в ОЗУ, 18,1°
;2600 об/мин
ldi R16, 15	;множитель
st X+, R16	;в ОЗУ, 19,5°
;2800 об/мин
ldi R16, 13	;множитель
st X+, R16	;в ОЗУ, 20,9°
;3000 об/мин
ldi R16, 11	;множитель
st X+, R16	;в ОЗУ, 22,3°
;3200 об/мин
ldi R16, 9	;множитель
st X+, R16	;в ОЗУ, 23,7°
;3500 об/мин
ldi R16, 7	;множитель
st X+, R16	;в ОЗУ, 25,1°
;3900 об/мин
ldi R16, 6	;множитель
st X+, R16	;в ОЗУ, 25,8°
;4200 об/мин
ldi R16, 4	;множитель
st X+, R16	;в ОЗУ, 27,2°
;4700 об/мин
ldi R16, 3	;множитель
st X+, R16	;в ОЗУ, 27,9°
;5100 об/мин
ldi R16, 3	;множитель
st X+, R16	;в ОЗУ, 27,9°
;5600 об/мин
ldi R16, 4	;множитель
st X+, R16	;в ОЗУ, 27,2°
;6100 об/мин
ldi R16, 29	;множитель
st X+, R16	;в ОЗУ, 9,7°
ret		;возврат в программу

;==таблица №2,углов опережения в ОЗУ==
;=======для метки 20°, шаг 0.7°=======
FuozTable2:
ldi R27, 0x02	;задаем "highX"=02
ldi R26, 0x00	;задаем "lowX"=00
;опережение при оборотах
;500 и ниже, об/мин
ldi R16, 36	;множитель
st X+, R16	;в ОЗУ, 4,8°
;600 об/мин
ldi R16, 36	;множитель
st X+, R16	;в ОЗУ, 4,8°
;700 об/мин
ldi R16, 36	;множитель
st X+, R16	;в ОЗУ, 4,8°
;800 об/мин
ldi R16, 36	;множитель
st X+, R16	;в ОЗУ, 4,8°
;900 об/мин
ldi R16, 35	;множитель
st X+, R16	;в ОЗУ, 5,5°
;1000 об/мин
ldi R16, 34	;множитель
st X+, R16	;в ОЗУ, 6,2°
;1100 об/мин
ldi R16, 34	;множитель
st X+, R16	;в ОЗУ, 6,2°
;1200 об/мин
ldi R16, 33	;множитель
st X+, R16	;в ОЗУ, 6,9°
;1300 об/мин
ldi R16, 32	;множитель
st X+, R16	;в ОЗУ, 7,6°
;1400 об/мин
ldi R16, 31	;множитель
st X+, R16	;в ОЗУ, 8,3°
;1500 об/мин
ldi R16, 30	;множитель
st X+, R16	;в ОЗУ, 9°
;1600 об/мин
ldi R16, 29	;множитель
st X+, R16	;в ОЗУ, 9,7°
;1700 об/мин
ldi R16, 28	;множитель
st X+, R16	;в ОЗУ, 10,4°
;1800 об/мин
ldi R16, 26	;множитель
st X+, R16	;в ОЗУ, 11,8°
;1900 об/мин
ldi R16, 24	;множитель
st X+, R16	;в ОЗУ, 13,2°
;2000 об/мин
ldi R16, 22	;множитель
st X+, R16	;в ОЗУ, 14,6°
;2100 об/мин
ldi R16, 20	;множитель
st X+, R16	;в ОЗУ, 16°
;2200 об/мин
ldi R16, 18	;множитель
st X+, R16	;в ОЗУ, 17,4°
;2300 об/мин
ldi R16, 16	;множитель
st X+, R16	;в ОЗУ, 18,8°
;2400 об/мин
ldi R16, 14	;множитель
st X+, R16	;в ОЗУ, 20,2°
;2500 об/мин
ldi R16, 13	;множитель
st X+, R16	;в ОЗУ, 20,9°
;2600 об/мин
ldi R16, 11	;множитель
st X+, R16	;в ОЗУ, 22,3°
;2800 об/мин
ldi R16, 9	;множитель
st X+, R16	;в ОЗУ, 23,7°
;3000 об/мин
ldi R16, 7	;множитель
st X+, R16	;в ОЗУ, 25,1°
;3200 об/мин
ldi R16, 6	;множитель
st X+, R16	;в ОЗУ, 25,8°
;3500 об/мин
ldi R16, 4	;множитель
st X+, R16	;в ОЗУ, 27,2°
;3900 об/мин
ldi R16, 2	;множитель
st X+, R16	;в ОЗУ, 28,6°
;4200 об/мин
ldi R16, 1	;множитель
st X+, R16	;в ОЗУ, 29,3°
;4700 об/мин
ldi R16, 0	;множитель
st X+, R16	;в ОЗУ, 30°
;5100 об/мин
ldi R16, 0	;множитель
st X+, R16	;в ОЗУ, 30°
;5600 об/мин
ldi R16, 1	;множитель
st X+, R16	;в ОЗУ, 29,3°
;6100 об/мин
ldi R16, 29	;множитель
st X+, R16	;в ОЗУ, 9,7°
ret		;возврат в программу

;==таблица №3,углов опережения в ОЗУ==
;=======для метки 20°, шаг 0.7°=======
FuozTable3:
ldi R27, 0x03	;задаем "highX"=03
ldi R26, 0x00	;задаем "lowX"=00
;опережение при оборотах
;500 и ниже, об/мин
ldi R16, 39	;множитель
st X+, R16	;в ОЗУ, 2,7°
;600 об/мин
ldi R16, 39	;множитель
st X+, R16	;в ОЗУ, 2,7°
;700 об/мин
ldi R16, 39	;множитель
st X+, R16	;в ОЗУ, 2,7°
;800 об/мин
ldi R16, 39	;множитель
st X+, R16	;в ОЗУ, 2,7°
;900 об/мин
ldi R16, 38	;множитель
st X+, R16	;в ОЗУ, 3,4°
;1000 об/мин
ldi R16, 37	;множитель
st X+, R16	;в ОЗУ, 4,1°
;1100 об/мин
ldi R16, 36	;множитель
st X+, R16	;в ОЗУ, 4,8°
;1200 об/мин
ldi R16, 36	;множитель
st X+, R16	;в ОЗУ, 4,8°
;1300 об/мин
ldi R16, 35	;множитель
st X+, R16	;в ОЗУ, 5,5°
;1400 об/мин
ldi R16, 35	;множитель
st X+, R16	;в ОЗУ, 5,5°
;1500 об/мин
ldi R16, 34	;множитель
st X+, R16	;в ОЗУ, 6,2°
;1600 об/мин
ldi R16, 34	;множитель
st X+, R16	;в ОЗУ, 6,2°
;1700 об/мин
ldi R16, 33	;множитель
st X+, R16	;в ОЗУ, 6,9°
;1800 об/мин
ldi R16, 32	;множитель
st X+, R16	;в ОЗУ, 7,6°
;1900 об/мин
ldi R16, 31	;множитель
st X+, R16	;в ОЗУ, 8,3°
;2000 об/мин
ldi R16, 29	;множитель
st X+, R16	;в ОЗУ, 9,7°
;2100 об/мин
ldi R16, 28	;множитель
st X+, R16	;в ОЗУ, 10,4°
;2200 об/мин
ldi R16, 26	;множитель
st X+, R16	;в ОЗУ, 11,8°
;2300 об/мин
ldi R16, 24	;множитель
st X+, R16	;в ОЗУ, 13,2°
;2400 об/мин
ldi R16, 22	;множитель
st X+, R16	;в ОЗУ, 14,6°
;2500 об/мин
ldi R16, 21	;множитель
st X+, R16	;в ОЗУ, 15,3°
;2600 об/мин
ldi R16, 19	;множитель
st X+, R16	;в ОЗУ, 16,7°
;2800 об/мин
ldi R16, 17	;множитель
st X+, R16	;в ОЗУ, 18,1°
;3000 об/мин
ldi R16, 16	;множитель
st X+, R16	;в ОЗУ, 18,8°
;3200 об/мин
ldi R16, 14	;множитель
st X+, R16	;в ОЗУ, 20,2°
;3500 об/мин
ldi R16, 13	;множитель
st X+, R16	;в ОЗУ, 20,9°
;3900 об/мин
ldi R16, 11	;множитель
st X+, R16	;в ОЗУ, 22,3°
;4200 об/мин
ldi R16, 10	;множитель
st X+, R16	;в ОЗУ, 23°
;4700 об/мин
ldi R16, 9	;множитель
st X+, R16	;в ОЗУ, 23,7°
;5100 об/мин
ldi R16, 7	;множитель
st X+, R16	;в ОЗУ, 25,1°
;5600 об/мин
ldi R16, 10	;множитель
st X+, R16	;в ОЗУ, 23°
;6100 об/мин
ldi R16, 29	;множитель
st X+, R16	;в ОЗУ, 9,7°
ret		;возврат в программу