Здравствуйте мальчики, здравствуйте девочки ... (с) В. Цой.

Итак, сейчас я расскажу вам, как правильно работать с прерываниями.

Надеюсь, вы уже познакомились с предыдущими разделами обучалки, потренировались писать программы и готовы идти дальше.

Начнем.

Как вы уже знаете, прерывания могут возникать практически в любой момент выполнения основной программы. Хотя обработчик прерывания стараются сделать максимально коротким, все же зачастую без вычислений внутри обработчика не обойтись. Как известно, вычисления (арифметические и логические операции) в архитектуре AVR можно прозиводить только с регистрами общего назначения (РОН) - r0-r31. Еще, вы, наверное, знаете, что о результатах вычислений и логических операций мы можем узнать из регистра состояния - SREG. Регистр SREG состоит из флагов :

C: (Carry Flag) Флаг переноса (бит 0)

Z: (Zero Flag) Нуль- флаг (бит 1)

N: (Negative Flag) Флаг отрицательного результата (бит 2)

V: (Two’s complement overflow indicator) Флаг переполнения дополнения до 2-х (бит 3)

S: (N ⊕ V, For signed tests) Флаг знака (бит 4)

H: (Half Carry Flag) Флаг полу-переноса (бит 5) 

T: (Transfer bit used by BLD and BST instructions) Буферный бит, используемый командами BLD и BST (бит 6)

I: (Global Interrupt Enable/Disable Flag) Флаг глобального разрешения/запрещения прерываний (бит 7)

Немного о самых используемых флагах

1. Флаг переноса - выставляется (т. е. бит C равен 1) когда результат выполнения операции превышает 255 

Например: 

[code]


ldi r16, 234
; загружаем в r16 число 234 


ldi r17, 235
; загружаем в r17 число 235 


add r16, r17
; складываем  регистр r16 с регистром r17

[/code]

В обычной арифметике 234+235 равно 469, но в микроконтролере AVR (да и других 8-ми битных) в данном случае результат не может превышать 255, потому что максимальное число, которое можно записать с помощью 8-ми бит равно 2^8-1 ((два в степени восемь) минус единица). Как же быть, когда результат больше? Так вот, в "микроконтроллерной" арифметике, если результат операции больше 255, выставляется флаг переноса, т. е. флаг переноса - это практически девятый бит результата. Поясню на нашем примере: если мы переведем наши числа в двоичную систему счисления то получим 11101010 + 11101011 = 111010101, т.е как видим результат получается длинной в девять бит. А что же произойдет в микроконтроллере? А вот что: младшие восемь бит, запишутся в r16, а старший пойдет в флаг переноса, т. е. после операции в r16 будет число 0b11010101 и в C будет единица (двоичная).

Установка флага переноса может происходить и при вычитании, в этом случае флаг переноса устанавливается, когда уменьшаемое меньше вычитаемого, т. е. разность получается отрицательной.

Еще один пример: команда lsl - логический сдвиг влево - работает следующим образом - она сдвигает число (в двоичной форме) на 1 бит влево, в младший бит записывается 0, а старший бит числа записывается в перенос

Например:

[code]


ldi r16, 0b10001001


lsl r16

[/code]

в результате выполнения операции r16 равен 0b00010010, С равно 0b1

Сделано так не случайно, флаг переноса используется для операций над числами с разрядностью больше 8 бит, но об этом в другой раз, сейчас надеюсь вы поняли, что такое флаг переноса.

2. Нуль- флаг - здесь попроще - нуль флаг устанавливается когда результат операции, а точнее младшие 8 бит результата равны 0.

Например:

[code]


ldi r16, 1
; загружаем в r16 число 1 


ldi r17, 255
; загружаем в r17 число 255 


add r16, r17
; складываем  регистр r16 с регистром r17

[/code]

В результате выполнения команды add установится и флаг переноса (C), и нуль-флаг (Z)

На этих двух флагах мы на этот раз закончим (скажу по секрету, об остальных флагах я знаю значительно меньше)

Так вот, теперь мы знаем, что о результате арифметических и логических операций можно судить по флагам регистра SREG.

Следует запомнить одно правило - в регистре SREG хранятся флаги результата последней выполненной команды, до тех пор, пока  не выполнится следующая команда, изменяющая флаги результата. Флаги изменяют только арифметические и логические команды, а команды пересылки данных (например mov, ld, st, in, out и многие другие)  и перехода - нет.

Посмотреть какие именно флаги изменяет команда можно в упомянутой мною ниже брошюре, либо в даташите (далее DS - от англ. DataSheet) в разделе Instruction Set Summary.

Например:

[code]


ldi r16, 1
; загружаем в r16 число 1  -  не изменяет флаги


ldi r17, 255
; загружаем в r17 число 255 - не изменяет флаги 


add r16, r17
; складываем  регистр r16 с регистром r17 - изменяет флаги

; после этих операций в регистре r16 находится 0, в регистре SREG установлены

; флаги Z и C (возможно и некоторые другие)


ldi r16, 70
; эта команда изменяет r16, но не изменяет флаги


lds r17, 0x60 
; то же, в r17 загружается ячейка памяти 0x60 но флаги не




; изменяются

; после произведенных действий в r16 будет число 70, в r17 будет содержимое

; ячейки ОЗУ с номером 0x60,  флаги Z и C (возможно и некоторые другие) 

; по-прежнему будут установлены


sub r16, r17 
; после выполнения этой команды изменятся флаги, хотя 




; они могут совпасть с предыдущими (в зависимости от




; того, какое число будет в r17) и внешне это изменение не




; будет заметно

[/code]

У вас может возникнуть вопрос: А зачем все эти флаги, ну посмотрел я на SREG и дальше что? Оказывается все не так просто - вспомните, например, команду  breq label - переход на метку если равно. А что равно чему? - вопрос. Так вот открою вам страшную тайну: при выполнении команды breq контроллер ничего ни с чем не сравнивает, он просто "смотрит" на флаг Z в регистре SREG, и если Z установлен (Z=1)  делает переход. Почему так? Просто предполагается, что перед командой breq вы выполнили, например, команду сравнения (cp  или cpi), которая виртуально, т. е. на самом деле не изменяя значения регистров вычитает первый операнд из второго, при этом, хоть значения регистров и не изменяются, флаги изменяются также как при "реальном" вычитании. В принципе можно и вычесть один операнд из другого, и если в результате вычитания получится 0 (т. е. операнды равны), то breq перескочит на метку. Вообще, если вы при выполнении любой операции установился флаг Z (Z стал равен 1), а следующая команда breq - то она перепрыгнет на метку. Вы наверное думаете, что все сложно - на самом деле не очень, нужно только уметь читать документы. У Atmel  есть замечательная брошюра AVR Instruction Set (Система команд архитектуры AVR) - ﻿www.atmel.com/atmel/acrobat/doc0856.pdf, в которой подробно описаны все команды, флаги, способы адресации и т. п. - рекомендую для прочтения, многие вопросы отпадают сами собой.

Вот уже сколько написано, а про прерывания еще ни слова - не торопитесь, сейчас все объясню.

Представьте себе, что в основной программе вы усиленно считаете какое-либо объемное арифметическое выражение, реализуете  сложный логический алгоритм или просто складываете пару чисел, и вдруг, как гром среди ясного неба, поступает запрос прерывания. Что будет делать контроллер? Докладываю, контроллер закончит выполнять операцию, на которую пришелся запрос прерывания, а затем выполнит этот запрос (при условии, что команда, на которую пришел запрос прерывания любая кроме cli). Как выполняется запрос прерывания? Очень просто - контроллер сохраняет в стеке адрес команды, следующей за той, на которую пришелся запрос,а затем прыгает на адрес соответствующего вектора прерывания и одновременно глобально запрещает прерывания (словно во время "прыжка" на свой вектор выполняет еще и команду cli). И вот мы уже в обработчике прерывания. В нем мы тоже можем выполнять разные математические действия, загружать константы и ячейки ОЗУ в регистры и т. п. А что произойдет после того, как мы завершим обработчик прерывания? И как вообще его завершать? Отвечаю, завершать обработчик прерывания рекомендуется командой reti, которая "вынимает" из стека адрес возврата, сохраненный при выполнении запроса прерывания и возвращается по этому адресу, при этом автоматически глобально разрешает прерывания (словно выполняет команду sei), которые, как мы помним, были запрещены контроллером при обработке запроса. 

А дальше? А дальше, выполнив команду reti, контроллер вернется к основной программе, т.е. к команде, следующей за той, на которую пришелся запрос прерывания. - Ну и что? - спросите вы. А, то, что после возврата, если не принять меры, регистры, которые вы до этого использовали для вычислений в основном цикле программы и флаги в регистре SREG могут иметь совсем не те значения, которые вы ожидаете, т. к. они могли измениться в прерываниях. 

Поясню на примере:

[code]


.cseg


.org 0


rjmp Reset


rjmp INT_0; прыгаем на метку INT_0


....
; остальные вектора опустим за ненадобностью



INT_0:



ldi r16, 2
; загружаем в r16 число 2  - флаги не изменяются



ldi r17, 3
; загружаем в r17 число 3 - флаги не изменяются



add r16, r17 
; складываем r16 и r17, результат в r16 - флаги изменяются


; после выполнения команды в r16 будет число 5, в  r17 - 3, в регистре SREG


; флаги C и Z будут сброшены (С=0, Z=0)



reti

; возвращаемся из прерывания


Reset: 


ldi r16, 1
; загружаем в r16 число 1  -  флаги не изменяются


ldi r17, 255
; загружаем в r17 число 255 -  флаги не изменяются


add r16, r17
; складываем   r16 с  r17 - флаги изменяются

; после этих операций в регистре r16 находится 0, в регистре SREG установлены

; флаги Z и C (возможно и некоторые другие)


ldi r16, 70
; эта команда изменяет r16, но  флаги не изменяются


lds r17, 0x60 
; то же, в r17 загружается ячейка памяти 0x60 но флаги не




; изменяются, допустим на эту команду пришел запрос 




; внешнего прерывания 0 (INT_0)

; после произведенных действий в r16 будет число 70, в r17 будет содержимое

; ячейки ОЗУ с номером 0x60,  флаги Z и C (возможно и некоторые другие) 

; по-прежнему будут установлены, и в это же время после этой команды будет

; совершен прыжок на вектор прерывания

; далее будет исполнен обработчик прерывания

; сюда мы вернемся из обработчика

; Напомню что мы имеем после возврата из обработчика:

;  в r16 будет число 5, в  r17 - 3, в регистре SREG флаги C и Z будут сброшены

; (С=0, Z=0)


breq label
; в результате эта команда не прыгнет на метку label т. к.




; Z=0, а выполнится следующая за ней команда


rjmp Reset
; вот эта

label:
;

; мы могли предполагать, что прыгнем на эту метку




; и это бы произошло, если бы не прерывания, но..


sub r16, r17 
;  этой команде в нашем примере не суждено выполниться

...

[/code]

Надеюсь, теперь читателям понятно, что я имел ввиду. Теперь попробую объяснить как с этим бороться. Идеология прерываний такова, что появляться они могут в любой момент времени и предсказать на какой из команд появится тот или иной запрос прерывания невозможно, однако приведенный пример показывает, что они могут вмешаться в логику работы программы. Чтобы этого не происходило как раз и придумали стек, который может быть использован не только для сохранения  адресов возврата подпрограмм, но и флагов и регистров. Как это сделать, сейчас поясню, как всегда - на примере.

﻿1. Сохранение регистров общего назначения (r0-r31) 

[code]

INT_0:


push r16 
; "заталкиваем" регистр r16 в стек 


push r17
 ; "заталкиваем" регистр r17 в стек 


; теперь мы можем пользоваться сохраненными регистрами как нам угодно 



...some code 


pop r17
; "вынимаем " регистры из стека обязательно в порядке обратном


 
; "заталкиванию" 


pop r16
; 

; теперь в регистрах появилисль значения, которые были в них до прерывания

reti

; можно выходить

[/code]

2. Сохранение регистра SREG в стеке: 

[code]


push r16; "заталкиваем" регистр r16 в стек 


in r16, SREG; читаем в r16 регистр SREG 


push r16; сохраняем прочитанное значение в стеке.


push r17
 ; "заталкиваем" регистр r17 в стек 

.... some code 


pop r17
; "вынимаем " регистры из стека обязательно в порядке обратном


 
; "заталкиванию" 


pop r16 
; читаем в r16 из стека значение, соответствующее регистру SREG 




; до вход в обработчик прерывания 


out SREG, r16 ; пишем это значение в SREG 


pop r16
; читаем из стека значение r16. 


; после данных действий и в SREG и в r16 значения которые были в них до


; входа в обработчик прерывания.

[/code]

Важное замечание: при операциях со стеком порядок извлечения регистров из стека всегда должен быть обратным относительно порядка сохранения, "заталкивания" регистров в стек.

Основное правило, если в обработчике прерывания используются арифметические или логические операции, то необходимо сохранять SREG в стеке. Поскольку напрямую "затолкать" этот регистр в стек нельзя, а можно только прочитать его в РОН, то в любом случае нужно сохранять в стеке и тот регистр, в который вы читаете SREG, причем сохранение этого регистра в стек нужно проводить до чтения, ибо после чтения вы уже изменили регистр, и это уже копия SREG.

Также необходимо сохранять в стеке все изменяемые в обработчике прерывания регистры общего назначения, если иное не предусмотрено логикой работы программы.

