Форум РадиоКот

Код: Выделить всё

	list p=16f84
	include	p16f84.inc
	include	PIC16F84_master_control.h
	include	Soft_UART_Lib_use_Timer0.h
	include	Matrix_keyboard.h
	include	Macro.h
	include	Commands.h

#define	DEBUG			no;yes;
	
if (DEBUG)
	__config	_CP_OFF & _WDT_OFF & _PWRTE_ON & _XT_OSC
else
	__config	_CP_OFF & _WDT_ON & _PWRTE_ON & _XT_OSC
endif

	org	LAST_DEV_ADDR
	de	DEFAULT_LAST_DEV_ADDR

PIC16F84_Master_Control	udata_shr
w_temp			res	1
status_temp		res	1
command			res	1
flags			res	1
addr_temp		res	1
last_dev_addr	res	1

	extern	TX_byte,RX_byte,key_char
	extern	Init_UART,Soft_UART_ISR,Send_TX_byte,Get_RX_byte,Delay_1bit
	extern	Init_Matrix_Keyboard,Matrix_Keyboard_ISR,Release_Key,Anti_Debounce
	global	flags	
	global	End_Interrupt_Heandler
;======================
RESET_VECTOR	code	0h
	goto	Init
;======================
ISR				code	4h				; Вектор прерывания
Interrupt_Heandler
	push								; Сохраним контекст
	btfsc	INTCON,RBIF
	goto	Matrix_Keyboard_ISR			; Если было прерывание по изминению состояния RB7-RB4, переходим на соответствующий обработчик
	goto	Soft_UART_ISR				; Иначе переходим к обрабочику программного UART			
End_Interrupt_Heandler
	pop									; Восстановим контекст	
	retfie

Init
	movlw	b'11001'
	movwf	PORTA
	banksel	TRISA
	movlw	b'11000'
	movwf	TRISA
	banksel	PORTA
	call	Init_UART
	btfss	Registry_PIN				; Если установлен джампер регистрации новых модулей	
	goto	Reg_New_Modules				; Переходим в режим прописки новых модулей
	btfss	STATUS,NOT_TO				; Проверяем сброс по WD
	bsf		RED_LED						; Был сброс по WD, зажгем светодиод ошибки, скорее всего не было ответа от модуля
Main
	call	Init_Matrix_Keyboard
	clrf	flags
	Send_Value	00h						; Выдаем в сеть признак наличия мастера сети
Wait_Command							; Первая нажатая кнопка - это команда
	bcf		YELLOW_LED					; Гасим Желтый
	clrwdt
	sleep
	nop
	btfss	Yes_Press					; Если не было нажатия, крутимся в цикле
	goto	Wait_Command
	bcf		INTCON,RBIE					; Запрещаем повторные прерывания по дребезгу
	ZUMER_ON							; Озвучим нажатие
	Anti_Debounce_macro
	movfw	key_char	
	movwf	command
	swapf	command,f					; начинаем формировать команду для передачи - переместим собстевенно команду в старшую тетраду
	bcf		Yes_Press					
	bcf		INTCON,RBIF					; Сбросим флаг возможно прошедшего прерывания от клавиатуры
	bsf		INTCON,RBIE					; Закончили преварительное формирование команды (пока без адреса), разрешаем прерывание клавиатуры (ждем 2 нажатия кнопки для формирования адреса модуля)
	ZUMER_OFF
	clrwdt
	sleep
Wait_Num_of_Module						; Вторая нажатая кнопка - это номер модуля
;	clrwdt								; Специально не будем сбрасывать WD, чтобы случае ошибочного нажатия 1 раз выйти из этого цикла по сбросу
	btfss	Yes_Press					; Если не было нажатия, крутимся в цикле
	goto	Wait_Num_of_Module
	bcf		INTCON,RBIE					; Запрещаем повторные прерывания по дребезгу
	ZUMER_ON							; Озвучиваем нажатие
	Anti_Debounce_macro
	movfw	key_char					; Сформируем номер модуля
	iorwf	command						; И наложим маской на команду, получая в переменной command номер модуля (младшая тетрада) и собственно команда (старшая тетрада)
	bcf		INTCON,RBIF					; Сбросим флаг возможно прошедшего прерывания от клавиатуры, после отправки команды будут автоматичски разрешены все прерывания
	bsf		INTCON,RBIE
	Send_Byte	command					; Отправляем скомпонированную команду в сеть		
	bcf		Yes_Press					; Обработали нажатие, сбросим флаг
	ZUMER_OFF
if	(USE_DOUBLE_REQEST)
	movfw	key_char					; Берем последнюю нажатую кнопку
	btfsc	STATUS,Z					; Если пакет широковещательный (адрес 0) - просто шлем команду 2 раз						
	goto	Send_without_repeat
	bsf		YELLOW_LED					; Зажигаем Желтый
	Get_Byte							; Принимаем ответ (зациклимся в ожидании, если ответ не прийдет в течении 2.3 сек, произойдет сброс МК)
	movfw	command						; Берем отправленную команду
	andlw	b'00001111'					; Сами формируем ожидаемый первый ответ на эту команду
	subwf	RX_byte,w					; Сравниваем с полученным ответом	
	btfss	STATUS,Z
	goto	Error_Section				; Не равны, ошибка
	Send_Byte	command					; Равны, повторно отправляем команду в сеть	
else
	movfw	key_char					; Берем последнюю нажатую кнопку
	btfsc	STATUS,Z					; Если пакет широковещательный (адрес 0) - пропускаем прием ответа						
	goto	Send_without_repeat_2
	bsf		YELLOW_LED					; Зажигаем Желтый
endif
	Get_Byte							; Принимаем ответ (зациклимся в ожидании, если ответ не прийдет в течении 2.3 сек, произойдет сброс МК)
	movfw	command						; Берем отправленную команду
	subwf	RX_byte,w					; Сравниваем с полученой командой	
	btfss	STATUS,Z
	goto	Error_Section				; Не равны, ошибка
Send_without_repeat_2
	bcf		RED_LED						; Гасим светодиод ошибки	
	goto	Wait_Command				; Команда выполнена, зациклимся

Error_Section
	bsf		RED_LED						; Зажгем светодиод ошибки (команда не была выполнена)
	goto	Wait_Command

if	(USE_DOUBLE_REQEST)
Send_without_repeat
	call	Delay_1bit					; Дадим модулю время разобрать первую копию команды	
	Send_Byte	command
	goto	Send_without_repeat_2
endif		

Reg_New_Modules
	bsf		YELLOW_LED
	call	Read_LAST_DEV_ADDR			; Считаем адрес последнего приписанного модуля в addr_temp
Loop_Registration
	incf	addr_temp					; Берем следующий адрес для записи
	movlw	0Fh							; Возможно это 15 адрес ? (достигли предела модулей)
	subwf	addr_temp,w
	btfsc	STATUS,Z
	goto	No_More_Modules	
Step_0
	Send_Value	0Fh						; Отсылаем команду опроса 15 модуля
	Get_Byte							; Ждем ответа в течении 2.3 сек, потом сброс МК, переинициализация контроллера и повторное попадание в эту ветку
	movlw	0Fh							; Ответ получен. Сравним отправленую команду с полученной
	subwf	RX_byte,w
	btfss	STATUS,Z	
	goto	Step_0						; Не иденитичны, повторная отправка
Step_1
	Send_Value	0FFh					; Идентичны модуль с номером 15 находиться в сети, начинаем процедуру смены адреса
	Get_Byte							; Ждем ответа в течении 2.3 сек, потом сброс МК, переинициализация контроллера и повторное попадание в эту ветку
	movlw	0Fh							; Ответ получен. Сравним ответ с образцом - командой опроса
	subwf	RX_byte,w
	btfss	STATUS,Z	
	goto	Step_1						; Не иденитичны, повторная отправка
Step_2
	Send_Value	0FFh					; Идентичны модуль с номером 15 готов к смене адреса, продолжаем процедуру смены адреса
	Get_Byte							; Ждем ответа в течении 2.3 сек, потом сброс МК, переинициализация контроллера и повторное попадание в эту ветку
	movlw	0FFh						; Ответ получен. Сравним отправленую команду с полученной
	subwf	RX_byte,w
	btfss	STATUS,Z	
	goto	Step_1						; Не иденитичны, повторная отправка первый раз	
Step_3
	swapf	addr_temp,w					; Перемещаем новый адрес в старшую тетраду
	iorlw	0Fh							; Накладываем маску адреса 15
	movwf	command						; Запоминаем полученную команду
	Send_Byte	command					; И отправляем
	Get_Byte							; Ждем ответа в течении 2.3 сек, потом сброс МК, переинициализация контроллера и повторное попадание в эту ветку 
	movfw	command						; Ответ получен. Сравним ответ с образцом - отправленой командой
	subwf	RX_byte,w
	btfss	STATUS,Z	
	goto	Step_0						; Не иденитичны, начинаем процедуру смены адреса заново
Step_4
	Send_Byte	command					; Повторно отправляем новый адрес
	Get_Byte							; Ждем ответа в течении 2.3 сек, потом сброс МК, переинициализация контроллера и повторное попадание в эту ветку 
	movfw	addr_temp					; Ответ получен. Сравним ответ с образцом - командой опроса нового адреса (совпадает с адресом)
	subwf	RX_byte,w
	btfss	STATUS,Z	
	goto	Step_0						; Не иденитичны, начинаем процедуру смены адреса заново
Step_5
	ZUMER_ON							; Пикнем зумером в знак того, что происходит запись нового адреса в EEPROM модуля
	movfw	addr_temp
	call	Write_LAST_DEV_ADDR			; Запомним последний приписанный адрес в EEPROM
	ZUMER_OFF
	goto	Loop_Registration			; Процедура приписки закончена успешно, ждем подключения следующего модуля

No_More_Modules							; Мы достигли максимального количества приписанных модулей
	clrf	addr_temp					; Обнуляем количество приписанных модулей
	movfw	addr_temp
	call	Write_LAST_DEV_ADDR			; И записываем 0 в соответствующую ячейку EEPROM
	clrwdt								
	sleep
	nop
	btfss	Registry_PIN				; Ожидаем снятия джемпера приписки модулей
	goto	$-3
	goto	Main