Форум РадиоКот

Код: Выделить всё

Send_byte:                              ; Send 1 bytes of informarion located in Accumulator
	mov     Bit_CNT,#8              ; Set bit count value
SB_Loop:
	rlc     A                       ; Send 1 data bit
	mov     SDA_pin,C               ; Put data bit on pin
	Release_SCL_High                ; Drive SCL HIGH
	Delay_3_Cycles                  ; Delay
	
	clr     SCL_pin                 ; Clear SCL
	Delay_3_Cycles                  ; Delay
	djnz    Bit_CNT,SB_Loop         ; Repeat until all bits sent
	
	setb    SDA_pin                 ; Release data line for acknowledge
	Release_SCL_High                ; Send clock for acknowledge
	Delay_4_Cycles                  ; Delay
	jnb     SDA_pin,SB_ex           ; Check for valid acknowledge bit
	setb    No_ACK                  ; Set status for no acknowledge
SB_ex:
	clr     SCL_pin                 ; Finish acknowledge bit
	Delay_3_Cycles			; Delay
	ret

Код: Выделить всё

WriteData_copy	equ     3h		; R3

dseg    at      7h                      ; Первые 8 регистров под свои нужды

Stack:                                  ; А дальше пойдет стек

cseg    at      0
	jmp     Main

include 'LCD_on_P0.asm'

Main:
	mov     SP,#Stack               ; Инициализируем стек
        call	Ini_LCD                 ; Инициализация LCD
       	mov     WriteData_copy,#41h     ; Запишем в видеобуффер код выводимого символа
	call    Write_LCD_Data          ; И выведем его на дисплей
	jmp     $                       ; Зациклимся
end

Код: Выделить всё

BF_Flag		equ	ACC.7
RS		equ     P3.5
RW		equ	P3.4
;E              equ     P3.6(WR) и 3.7(RD) через 74НС04, взводится автоматически, при выполнении команды работы с внешней памятью
LCD_Port        equ     P0

WriteData       equ     3h              ; R3

; Не использовать для своих целей R0,R1,R2 они используются для формирования задержек
; Флаг занятости BF, пока 1 - LCD занят, когда 0 - LCD свободен, можно слать команды

cseg

Ini_LCD:                        	; Инициализация LCD
	call	Del_30ms		; Стартовая задержка на 30 мс по даташиту
        mov	LCD_Port,#00111100b	; DL=1, N=1, F=1
	call	Write_LCD_Ini           ; Запись инициализирующей команды
	call	Del_39mks               ; Задержка на 39 мкс по даташиту
	mov	LCD_Port,#00001100b	; D=1, C=0, B=0
	call	Write_LCD_Ini           ; Запись инициализирующей команды
	call	Del_39mks               ; Задержка на 39 мкс по даташиту
	mov	LCD_Port,#00000001b	; Очистим дисплей
	call	Write_LCD_Ini           ; Запись инициализирующей команды
	call	Del_1_53ms              ; Задержка на 1,53 мс по даташиту
	mov	LCD_Port,#00000110b	; I/D=1, SH=0
        call	Write_LCD_Ini           ; Запись инициализирующей команды
	ret

Write_LCD_Data:				; Запись данных из ACC в дисплей
	clr     RS                      ; Подаем команды, поетому опускаем RS
	setb	RW			; Будем читать флаг BF, поетому поднимаем RW
	push	ACC
Wait_Write_Data:
	movx	A,@R0	        	; Считываем состояние линий в аккумулятор, при этом дергаем Е дисплея пином Р3.7 (RD) через 74НС04
	jb	BF_Flag,Wait_Write_Data ; И проверяем флаг BF
	clr	RW			; Проверили флаг BF, можно опустить RW
	setb	RS                      ; Передаем данные, поетому поднимаем RS	
	mov	A,#WriteData
	movx	@R0,A                   ; Собственно запись данных, при этом дергаем Е дисплея пином Р3.6 (WR) через 74НС04
	pop	ACC
	ret

Write_LCD_Comm:                 	; Запись команды из ACC в дисплей
	clr     RS                      ; Подаем команды, поетому опускаем RS
	setb	RW			; Будем читать флаг BF, поетому поднимаем RW
	push	ACC
Wait_Write_Comm:
	movx	A,@R0			; Считываем состояние линий в аккумулятор, при этом дергаем Е дисплея пином Р3.7 (RD) через 74НС04
	jb	BF_Flag,Wait_Write_Comm ; И проверяем флаг BF
	clr	RW			; Проверили флаг BF, можно опустить RW 	
	mov	A,#WriteData
	movx	@R0,A                   ; Собственно запись команды, при этом дергаем Е дисплея пином Р3.6 (WR) через 74НС04
	pop	ACC
	ret
	
Write_LCD_Ini:				; Запись инициализируещих команд в дисплей, здесь не анализируется флаг BF
	clr     RS                      ; Подаем команды, поетому опускаем RS
	clr	RW                      ; Чтения флага BF не будет, поетому опускаем RW
	push	ACC
	mov	A,#LCD_Port		; Закинем иницализирующую команду в А
	movx	@R0,A                   ; Собственно запись команды, при этом дергаем Е дисплея пином Р3.6 (WR) через 74НС04
	pop	ACC
	setb	RS                      ; Поднимем назад RS
	setb	RW                      ; Поднимем назад RW
	ret

Del_30ms:
	mov	R2, #2h
	mov	R1, #8Dh
	mov	R0, #33h
	djnz	R0, $
	djnz	R1, $-4
	djnz	R2, $-8
	mov	R0, #32h
	djnz	R0, $
        ret
        
Del_1_53ms:
	mov	R1, #6h
	mov	R0, #7Fh
	djnz	R0, $
	djnz	R1, $-4
        ret
        
Del_39mks:
        mov	R0,#20
	djnz	R0,$
	ret
	
end