Форум РадиоКот

Код: Выделить всё

.def temp=r16
.def sum=r17

ANY_PROC:
     push temp //на всякий случай сохраняем временные регистры
     push sum
     in sum,PINB //считывание состояний кнопок. Наверное, и ввод и вывод в PORTD ошибка, пусть кнопки висят на PORTB
     mov temp,sum
     lsr temp //сдвиг на 1 байт
     andi sum,0x55 //первое волшебное число
     andi temp,0x55
     add sum,temp
     mov temp,sum
     lsr temp //сдвиг на 2 байта
     lsr temp
     andi sum,0x33 // второе волшебное число
     andi temp,0x33
     add sum,temp
     mov temp,sum
     swap temp //сдвиг на 4 байта, старший полубайт в данном случае неважен, он будет отрезан andi sum,0x0F
     add sum,temp
     andi sum,0x0F // третье волшебное число
//проверки. Поскольку предыдущая часть считает лог.1, сравнивать надо отпущенные кнопки, а не нажатые.
     cpi sum,0
          breq BTN_8
     cpi sum,6
          breq BTN_2
FUNC_END: //конец процедуры, посстанавливаем сохраненные значения
     pop sum
     pop temp
ret
BTN_8:
     sbi PORTD,1
rjmp FUNC_END
BTN_2:
     cbi PORTD,1
rjmp FUNC_END

Код: Выделить всё

void button(void)
{
unsigned char a,i;
for(i=0;i<8;i++)
   {
    if((PIND&(1<<i))==0)   //проверяем в цикле все порты D
       {a++;}   //считаем сколько кнопок вкл/выкл
   }
if(a==6)   // если 2 из 8 выключены
   {
   //что то делаем....
   }
if(a==8)   // если все включены
   {
   //что то делаем....
   }
a=0;
}