Форум РадиоКот

Код: Выделить всё

;
;          trbspi_sb1.txt
;
; файл протокола приемопередатчика проекта UPGM
; для блока подчиненной периферии(PAVR)
; /slave board/
;
;
;----------------------------------------------
;
; .equ bus_dtr = 0 ; шина данных/запроса доступа
        ; локализация в PORTA PAVR
        ; по reset вход с внешней подтяжкой к +5 вольт
        ; при запросе выход с активным уровнем 0
        ; при обмене соответственно или вход или выход
				; с данными в прямом коде
; .equ bus_clc = 1 ; тактовый строб обмена данными
        ; локализация в PORTA PAVR
        ; по reset/cold init вход с внешней подтяжкой к +5 вольт
        ; при обмене соответственно вход(прием) или выход(передача)
        ; активный уровень 0
; .equ bus_qt = 0 ; шина квитирования
        ; локализация в PORTD PAVR
        ; по reset/cold init вход с внешней подтяжкой к +5 вольт
        ; активный уровень 0
        ; вход для передатчика, выход для приемника
;
;----------------------------------------------
;
; .def data_t = r11 ; регистр (урезан) данные данных trbspi_sb
;
;----------------------------------------------
;
; данные флаги размещены в регистре РСФ GPIOR0
; или по псевдониму доступа через ОЗУ (GPIOR0+0x20)
;
; .equ data_key = 0 ; (GPIOR0) флаг  типа данные/команда
           ; data_key=0 - байт с данными
           ; data_key=1 - байт с командой
;
;
;
;----------------------------------------------
;
; тактовая частота системного генератора 8МГц
;
;----------------------------------------------
;
;     настройки портов относительно PSPI
;
;   исходно по reset 
;   DDRA=00000000
;   PORTA=00000000
;  входы с Z-состоянием
;   DDRB=00000000
;   POTTB=00000000
;  входы с Z-состоянием
;   DDRD=00000000
;   POTTD=00000000
;  входы с Z-состоянием
;  В init проводим отключение подтягивающих резисторов
;	 MCUCR.PUD=1
; и устанавливаем PORTD.ptr_clc = 0 DDRD.ptr_clc = ВЫХОД (1)
;
;----------------------------------------------
;
; модуль передачи
;
; собственно передача data_key и байта данных
; перед вызовом программы
; данные должны быть загружены в
; data_t (r11)
; и установлен в соответствие флаг data_key
;(data_key=0 - байт с данными
           ; data_key=0 - байт с командой)
;
;
 pspi_txd:
  push tmp0 ; служебный буфер-времянка
  push tmp1 ; счетчик бит
  push tmp2 ; счетчик таймера интервалов
  cbi DDRA,bus_dtr
  cbi DDRA,bus_clc
  cbi DDRD,bus_qt ; предварительно настроено
             ; bus_dtr=bus_clc=bus_qt=ВХОД (через внешнюю
             ; подтяжку = 1)
  cbi PORTA,bus_dtr ; подготовлено к выдаче bus_dtr=0
              ; вывод bus_dtr=1
  cbi PORTA,bus_clc ; подготовлено к выдаче bus_clc=0
              ; вывод bus_clc=1
  cbi PORTD,bus_qt ; подготовлено к выдаче bus_qt=0
              ; вывод bus_qt=1
 tx_on:
    ldi tmp1,8 ; счетчик бит загружен
    in tmp0,GPIOR0 ; читаем флаг data_key
     rcall strob ; бит типа данных передан
 data_tx:
   mov tmp0,data_t
   rcall strob ; бит данных передан
   lsr tmp0 ; постсдвиг значения данных
   mov data_t,tmp0 ; используется вывод данных из tmp0.0
   dec tmp1
   brne data_tx
 tx_off:
   pop tmp2
   pop tmp1
   pop tmp0
  ret
;----------------------------------------------------------
 strob:
    sbrs tmp0,0
    sbi DDRA,bus_dtr ; if tmp0,0=0 --> вывод bus_dtr=0
    sbrc tmp0,0
    cbi DDRA,bus_dtr ; if tmp0,0=1 -->  вывод bus_dtr=1
		    ; вывод в соответствии нулевого бита из tmp0,0
			; на PORTA,bus_dtr
		 rcall time ; задержка установки данных
		sbi DDRA,bus_clc ; активируем запрос синхронизации
		       ; ранее в PORTA.bus_clc установлен 0
		 rcall time ; задержка установки данных
 tx_tp0:
    sbic PIND,bus_qt
   rjmp tx_tp0 ; ожидание ответа приемника (bus_qt=0)
    cbi DDRA,bus_clc ; деактивируем запрос синхронизации
     ; bus_clc=ВХОД
     ; единица на bus_clc формируется за счет внешнего
     ; подтягивающего резистора
    cbi DDRA,bus_dtr ; вывод bus_dtr=1
                  ; разворот шины данных на ВХОД
    rcall time ; задержка установки данных
 tx_tp1:
    sbis PIND,bus_qt
   rjmp tx_tp1 ; ожидание ответа приемника (bus_qt=1)
     rcall time ; задержка установки данных
   ret
;----------------------------------------------------------
time:
    ldi tmp2,10 ; интервал ~40uS период = 0,00004*5= ~0,0002 бита/секунду
 ttime:
   nop ;
   dec tmp2
   brne ttime
   ret
;----------------------------------------------------------
;

;
;----------------------------------------------
;
;             модуль приема
;
; не имеет защиты от превышения ожидания длительности строба
; сопровождения исходя из предположения, что обмен между модулями
; является основной частью программы в промежутках между исполнением
; команд
; т.е. допускается полный останов обмена
;
; при выходе
;
; в data_t принятые данные в прямом коде
; флаг GPIOR0.data_key=1 принята команда
; флаг GPIOR0.data_key=0 приняты данные
;
;
 pspi_rxd:
   push tmp0 ; буфер обмена
   push tmp1 ; счетчик бит
   push tmp2 ; счетчик таймера интервалов
   cbi DDRA,bus_dtr
   cbi DDRA,bus_clc
   cbi DDRD,bus_qt ; предварительно настроено на
             ; шины bus_dtr=bus_clc=bus_qt=ВХОД, bus_dtr=bus_clc=bus_qt1=1
   cbi PORTA,bus_dtr ; подготовлено к выдаче bus_dtr=0
              ; вывод bus_dtr=1
   cbi PORTA,bus_clc ; подготовлено к выдаче bus_clc=0
              ; вывод bus_clc=1
   cbi PORTD,bus_qt ; подготовлено к выдаче bus_qt=0
              ; вывод bus_qt=1
 rx_on:
     rcall strobinp ; флаг типа данных получен
    sbrs tmp0,7
     cbi GPIOR0,data_key
    sbrc tmp0,7
     sbi GPIOR0,data_key ; флаг типа данных размещен
    ldi tmp1,8 ; загрузить счетчик бит
 data_rx:
    rcall strobinp ; текущий бит данных получен
     dec tmp1
      brne data_rx
     mov data_t,tmp0 ; данные переданы в data_t
   pop tmp2
   pop tmp1
   pop tmp0
  ret
;-------------------------------------------------------------
 strobinp:
   sbic PINA,bus_clc ; простой в ожидании PORTA.bus_clc=0
         ; ***!!! выполняется БЕЗ ОГРАНИЧЕНИЯ НА ВРЕМЯ ОЖИДАНИЯ !!!***
    rjmp strobinp
     rcall time ; задержка установки данных
      sbis PINA,bus_dtr
    clc
   sbic PINA,bus_dtr
    sec
     ror tmp0 ; заносим значение текущего PINA.bus_dtr в старший бит tmp0
    sbi DDRD,bus_qt ; актвировать строб квитирования
		          ; bus_qt=ВЫХОД с предварительно заданным
		          ; (cbi PORTD,bus_qt) значением =0
     rcall time ; задержка установки данных
 rx_tp1:
     sbis PINA,bus_clc ; простой в ожидании PORTA.bus_clc=1
         ; ***!!! выполняется БЕЗ ОГРАНИЧЕНИЯ НА ВРЕМЯ ОЖИДАНИЯ !!!***
    rjmp rx_tp1
      cbi DDRD,bus_qt ; деактвировать строб квитирования
         ; bus_qt=ВХОД, единица устанавливается за счет внешнего
         ; подтягивающего резистора
    rcall time ; задержка установки данных
   ret
;
;----------------------------------------------
;