Форум РадиоКот

Код: Выделить всё

----------------------------------------------------------------------------------
--
--  ИНДИКАТОР ШЕСТНАДЦАТЕРИЧНЫХ КОДОВ
-- 
--   По шине Hexs[15:0] поступают прямые коды четырёх шестнадцатеричных цифр, ко-
-- торые должны быть отображены на четырёхразрядном семисегментном индикаторе, а
-- по шине Points[3:0] - обратные сигналы зажигания точек, относящихся к этим циф-
-- рам (активный уровень низкий).
--   Выходными являются шины Segs[7:0] и Anodes[3:0], подаваемые на индикаторы
-- (активный уровень низкий). В каждый момент времени может быть активна только
-- одна из линий Anodes, поскольку используется мультиплексирование выходных
-- линий.
--   Сигнал Enable разрешает работу индикатора. Когда он равен нулю, индикатор бу-
-- дет погашен.
--   Сигнал Clock определяет частоту мультиплексирования. Для нормального отобра-
-- жения необходимо поддерживать её в пределах от 60 Гц до 1 кГц.
--
----------------------------------------------------------------------------------

library IEEE;
use IEEE.STD_LOGIC_1164.ALL;
use IEEE.NUMERIC_STD.ALL;
use IEEE.STD_LOGIC_UNSIGNED.ALL;


entity HexInd is
   port ( Hexs   : in  std_logic_vector (15 downto 0);
          Points : in  std_logic_vector (3 downto 0);
          Enable : in  std_logic;
          Clock  : in  std_logic;
          Segs   : out std_logic_vector (7 downto 0);
          Anodes : out std_logic_vector (3 downto 0));
end HexInd;


architecture Behavioral of HexInd is

   signal Counter : std_logic_vector (1 downto 0);
   signal Hex     : std_logic_vector (3 downto 0);
   signal Point   : std_logic;
   signal SegInt  : std_logic_vector (7 downto 0);
   signal AnInt   : std_logic_vector (3 downto 0);

begin

   -- Обработка сигнала разрешения индикации
   Segs <= SegInt when Enable = '1' else "11111111";
   Anodes <= AnInt when Enable = '1' else "1111";

   -- Счётчик мультиплексирования
   process(Clock) is
   begin
      if rising_edge(Clock) then
         Counter <= Counter + 1;
      end if;
   end process;

   -- Мультиплексор
   with Counter select
      Hex <= Hexs(3 downto 0) when "00",
             Hexs(7 downto 4) when "01",
             Hexs(11 downto 8) when "10",
             Hexs(15 downto 12) when others;

   with Counter select
      SegInt(7) <= Points(0) when "00",
                   Points(1) when "01",
                   Points(2) when "10",
                   Points(3) when others;

   with Counter select
      AnInt <= "1110" when "00",
               "1101" when "01",
               "1011" when "10",
               "0111" when others;

   -- Преобразователь кода цифры в код индикатора
   with Hex select
      SegInt(6 downto 0 ) <= "1000000" when "0000",
                             "1111001" when "0001",
                             "0100100" when "0010",
                             "0110000" when "0011",
                             "0011001" when "0100",
                             "0010010" when "0101",
                             "0000010" when "0110",
                             "1111000" when "0111",
                             "0000000" when "1000",
                             "0010000" when "1001",
                             "0001000" when "1010",
                             "0000011" when "1011",
                             "1000110" when "1100",
                             "0100001" when "1101",
                             "0000110" when "1110",
                             "0001110" when others;

end Behavioral;