Форум РадиоКот

Код: Выделить всё

DO_CRC:
PUSH	ACC    ; сохраняем аккумулятор
PUSH	B    ; сохраняем регистр В
PUSH	ACC    ; сохраняем байт данных
MOV	B, #8    ; кол-во битов (счетчик циклов)
CRC_LOOP: 
XRL	A, CRC    ; XOR с предыдущим значением контрольной суммы
RRC	A    ; сдвиг вправо через флаг переноса
MOV	A, CRC    ; берем последнее значение CRC
JNC	ZERO    ; переход, если не было переноса
XRL	A, #18H    ; обновляем значение CRC путем XOR с константой
ZERO: 
RRC	A    ; снова сдвигаем CRC
MOV	CRC, A    ; сохраняем новое значение CRC
POP	ACC    ; восстанавливаем байт данных
RR	A    ; циклически сдвигаем вправо
PUSH	ACC    ; снова сохраняем значение
DJNZ	B, CRC_LOOP    ; повторяем цикл 8 раз (для каждого бита)
POP	ACC    ; очищаем стек
POP	B    ; восстанавливаем прежние значения регистров из стека
POP	ACC 
RET    ; завершение процедуры

Код: Выделить всё

start:

	clrf	crc
	movlw	1
	call	crc_8	; crc = 0x5e

Код: Выделить всё

;
; Вычисление CRC по AN27
; Нужны 3 временных байта в ОЗУ: TempBuf, temp_crc, bitcntr
; и сама переменная crc, которую перед использованием надо инициализировать.
;
DO_CRC:
	movwf	TempBuf		; save bits to be shifted
	movlw	8		; set shift=8bits
	movwf	bitcntr
CRC_LOOP:
	movf	       TempBuf, w
	xorwf	crc, w		; calculate CRC
	movwf	temp_crc
	rrf	  temp_crc	; move it to the carry
	movlw	0x18
	btfsc	status, c	; skip if data=0
	xorwf	crc		; update the CRC value
	rrf	  crc		; position the new CRC
	bcf	  status, c
	rrf	  TempBuf		; get the remaining bits
	btfsc	status, c	; position the next bit
	bsf	  TempBuf, 7	; save the remaining bits
	decfsz	bitcntr		; repeat for eight bits
	goto	  CRC_LOOP
	return
;

Код: Выделить всё

start:

	clrf	crc
	movlw	1
	call	crc_8	; crc = 0x5e

	clrf	crc
	movlw	2
	call	crc_8	; crc = 0xbc

	clrf	crc
	movlw	4
	call	crc_8	; crc = 0x61

	clrf	crc
	movlw	8
	call	crc_8	; crc = 0xc2

	clrf	crc
	movlw	0x10
	call	crc_8	; crc = 0x9d

	clrf	crc
	movlw	0x20
	call	crc_8	; crc = 0x23

	clrf	crc
	movlw	0x40
	call	crc_8	; crc = 0x46

	clrf	crc
	movlw	0x80
	call	crc_8	; crc = 0x8c

Код: Выделить всё

 cblock	0x20

	crc

  endc

  org 0

	goto	start

;=========
crc_8:
	xorwf	crc,f
	clrw

	btfsc	crc,0
	xorlw	0x5e

	btfsc	crc,1
	xorlw	0xbc

	btfsc	crc,2
	xorlw	0x61

	btfsc	crc,3
	xorlw	0xc2

	btfsc	crc,4
	xorlw	0x9d

	btfsc	crc,5
	xorlw	0x23

	btfsc	crc,6
	xorlw	0x46

	btfsc	crc,7
	xorlw	0x8c

	movwf	crc

	return

;=========
start:



  ; dallas example:

	clrf	crc
	movlw	0x02
	call	crc_8	; crc = 0xbc

	movlw	0x1c
	call	crc_8	; crc = 0xaf

	movlw	0xb8
	call	crc_8	; crc = 0x1e

	movlw	0x01
	call	crc_8	; crc = 0xdc

	movlw	0x00
	call	crc_8	; crc = 0xf4

	movlw	0x00
	call	crc_8	; crc = 0x15

	movlw	0x00
	call	crc_8	; crc = 0xa2

	movlw	0xa2
	call	crc_8	; crc = 0x00

	goto	start

  end