ANALOG писал(а):
ТС, попробуйте вот такой код:
Код: Выделить всё
.cseg
rjmp start
.def tmp=R16
.def counter=R17
.def nulreg=R19
.org OC1Aaddr
rjmp Obrabot
Для AVR с памятью 16кБ нужно писать не rjmp, а jmp. В таблице векторов прерываний под каждый вектор отводится 2 слова памяти, а не одно. Пусть тредстартер сразу привыкает писать правильно.
И тему, на которую я дал ссылку ранее, тоже стоит изучить. Так, как оформил таблицу векторов прерываний тредстартер, а равно и так, как написали Вы, нельзя. И в той теме я писал, почему, и чем чревато иное оформление таблицы. Приводил пример того, как это нужно делать правильно.
И еще
Код: Выделить всё
ldi tmp, 0b00000000 ;здесь лучше записать просто 0, а не ~(1<<PD5), т.к. ~(1<<PD5) = 11011111, а лишние порты на вывод - это нехорошо
С точностью до наоборот.
конструкция вида
установит бит 5. а не сбросит. То есть, код
даст в регистре tmp результат 0b00100000, а не 0b11011111. Попробуйте в симуляторе.
А тредстартеру я, пожалуй, тоже посоветую пользоваться симулятором (например, AVR Studio) для отладки "логики" программы. Там сразу будет видно, как массивы заполняются, как прерывание вызывается и так далее. На все вопросы тредстартер получит ответ самостоятельно. Это и для наработки опыта полезно.
И еще рекомендация тредстартеру - пишите комментарии. Сам в начале сталкивался с этим. Напишешь программу, вроде все в ней понятно. А потом вернешься к ней через полгодика - уже ничего не помнишь. Приходится заново вникать.
Позволю себе привести пример того, как пишу программы я. Привожу кусок обработчика прерывания по приему байта по UART, взятый из одной разработки:
Спойлер
Код: Выделить всё
;Подпрограмма обработки прерывания по получению байта по USART --------------------------------------------------------------------------
adrURXC: ;USART RX Complete Handler
push R16 ;Сохранить на стеке рег.R16
in R16,SREG ;Сохранить на стеке
push R16 ;регистр состояния SREG
push YL ;Сохранить на стеке
push YH ;рег.пару Y
push R17 ;Сохранить на стеке рег.R17
push R18 ;Сохранить на стеке рег.R18
lds R16,UDR0 ;Занести принятый по USART байт в рег.R16
lds R17,RECVBYT ;Занести в рег.R17 кол-во принятых байт пакета
tst R17 ;Кол-во принятых байт равно нулю? (это первый байт пакета?)
brne USRXC2 ;Если нет, то переход на метку USRXC2
;Принят первый байт пакета (байт адреса)
;Инициализировать таймер 2 на отсчет 5мс, за которые весь пакет должен быть принят
USRXC1: ;
;Инициализировать таймер-счетчик 2 на отсчет интервала 5 мс. По окончанию интервала - сбрасывать USART и обнулять счетчик принятых байт
lds YL,FLAGS ;Занести в рег.YL содержимое ячейки FLAGS
andi YL,NONSELDELAY ;Обнулить бит SELDELAY для того, чтобы переполнение таймера-счетчика 2 обрабатывалось как отсчет
;времени приема пакета запроса
sts FLAGS,YL ;Сохранить в памяти новое значение ячейки FLAGS
ldi YL,0x9F ;Инициализировать таймер-счетчик
sts TCNT2,YL ;на отсчет 5мс при тактовой частоте 20МГц и коэффициенте деления 1024
ldi YL,0x07 ;Запустить таймер-счетчик 2
sts TCCR2B,YL ;с коэффициентом деления тактовой частоты 1024
ldi YL,(1<<TOIE2) ;Разрешение прерываний
sts TIMSK2,YL ;по переполнению таймер-счетчика 2
rjmp USRXC3 ;Перейти на метку USRXC3 для записи принятого байта в буфер принимаемого пакета
;Принят не первый байт пакета
USRXC2:
cpi R17,0x02 ;Принят третий байт пакета?
brne USRXC3 ;Если нет, то переход на метку USRXC3
;Принят третий байт пакета, откорректировать длину принимаемого пакета
ldi YL,0x05 ;В рег. YL занести кол-во служебных байт пакета (без учета длины поля данных)
add YL,R16 ;Теперь в рег.YL общая длина принимаемого пакета
sts LONGRECV,YL ;Сохранить новое значение длины пакета в ячейке LONGRECV
;Запись полученного по USART байта в буфер принимаемого пакета
USRXC3:
ldi YL,low(BUFRECV) ;Занести в рег.пару Y
ldi YH,high(BUFRECV) ;адрес начала буфера принимаемого пакета
add YL,R17 ;Прибавить к адресу начала буфера смещение,
brcc USRXC4 ;соответствующее адресу текущего
inc YH ;принимаемого байта
USRXC4:
st Y,R16 ;Сохранить текущий принятый байт в буфер принимаемого пакета
lds R16,LONGRECV ;Занести в рег.R16 длину принимаемого пакета
inc R17 ;Инкремент кол-ва принятых байт
cp R17,R16 ;Принят весь пакет данных?
brlo USRXC4_0 ;Если кол-во принятых байт меньше длины пакета, то пакет принят не полностью,
;переход на метку USRXC100
rjmp USRXC4_1 ;Иначе пакет принят полностью, перейти на метку USRXC4_1
USRXC4_0:
rjmp USRXC100 ;Пакет принят не полностью, перейти на метку USRXC100
USRXC4_1:
;Иначе принят весь пакет, рассчитать CRC принятого пакета
subi R17,0x02 ;Вычислить длину пакета за вычетом двух байт CRC
sts LENPAK,R17 ;Занести уменьшенную на 2 длину пакета в ячейку LENPAK
ldi YL,low(BUFRECV) ;Занести в рег.пару Y
ldi YH,high(BUFRECV) ;адрес начала буфера принимаемого пакета
call CRC ;Вызвать подпрограмму расчета CRC, результат в ячейках CRC_L и CRC_H
ldi YL,low(BUFRECV) ;Занести в рег.пару Y
ldi YH,high(BUFRECV) ;адрес начала буфера принимаемого пакета
add YL,R17 ;Прибавить к адресу начала буфера смещение,
brcc USRXC5 ;соответствующее адресу текущего
inc YH ;принимаемого байта
;Сейчас в рег.паре Y адрес младшего байта CRC принятого пакета
USRXC5:
ld R17,Y+ ;Занести в рег.R17 ст.байт принятой CRC
lds R16,CRC_H ;Занести в рег.R16 ст.байт рассчитанной CRC
cp R16,R17 ;Сравнить рассчитанный и принятый младшие байты CRC
brne USRXC_BAD ;Если они не равны, перейти на метку USRXC_BAD для отмены принятия пакета
ld R17,Y ;Занести в рег.R17 мл.байт принятой CRC
lds R16,CRC_L ;Занести в рег.R16 мл.байт рассчитанной CRC
cp R16,R17 ;Сравнить рассчитанный и принятый старшие байты CRC
brne USRXC_BAD ;Если они не равны, перейти на метку USRXC_BAD для отмены принятия пакета
;CRC принятого пакета верна
ldi YL,low(BUFRECV) ;Занести в рег.пару Y
ldi YH,high(BUFRECV) ;адрес первого байта, хранящего адрес целевого детектора
ld R16,Y+ ;Занести в рег.R16 байт KOPLEN
;Проверка предназначения пакета
lds R17,ADDRESS ;Занести в рег.R17 собственный адрес детектора
cp R16,R17 ;Сравнить собственный адрес с адресом целевого детектора
breq USRXC6 ;Если адреса равны, переход на проверку кода команды
rjmp USRXC_BAD ;Иначе пакет предназначен для другого детектора
С первого взгляда кажется, что такой стиль требует гораздо бОльшего времени для написания кода, но это не так. А уж при отладке и сопровождении программы экономит кучу времени.
Наверное, после команды
