Форум РадиоКот

Здесь можно немножко помяукать :)
https://radiokot.ru/forum/

Светодиодная сосулька - индикатор уровня

https://radiokot.ru/forum/viewtopic.php?t=61317

Страница 12 из 13

Re: Светодиодная сосулька - индикатор уровня

Добавлено: Вс фев 19, 2017 21:42:42
fannat
ткните носом в прошивку на 20 светодиодов, брал на другом сайте (там 10 прошивок с разной задержкой) прошивал двумя разными и обе криво работают(некоторые светодиоды не горят или горят дольше положенного)

Re: Светодиодная сосулька - индикатор уровня

Добавлено: Пн фев 20, 2017 10:06:16
yuritmics
И не забываем шить eeprom.

Re: Светодиодная сосулька - индикатор уровня

Добавлено: Пн фев 20, 2017 20:16:29
fannat
yuritmics писал(а):И не забываем шить eeprom.
спасибо, нужно еще реаниматор для тиньки спаять)

Re: Светодиодная сосулька - индикатор уровня

Добавлено: Ср дек 06, 2017 17:09:56
kot2004
Кто-нибудь, можете выложить программу для сосульки (которая описана в статье http://radiokot.ru/circuit/light/run/48/) на языке С с русскими комментариями!

Re: Светодиодная сосулька - индикатор уровня

Добавлено: Чт дек 07, 2017 07:51:14
Engineer_Keen
Как автор вышеприведенной статьи объясняю: программа для сосульки написана на АССЕМБЛЕРЕ.
Спойлер

Код: Выделить всё

;+--------------------------------------------------------------------+
;|Program:	Сосулька + индикатор уровня, 12 светодиодов, ШИМ 3 бит|
;|Autor:	EngineerKeen                                          |
;|DATE:		14.01.14                                              |
;|Hardware:	ATTiny13, 9.6MHz                                      |
;+--------------------------------------------------------------------+
.include "tn13def.inc"
.include "MacroAvr.asm"

	.def	ZERO=R0	;просто ноль
	.def	STR=R13	;для сохранения SREG в прерываниях без стека
	;def R1-R12 = Значения ШИМ каналов

	.def	FRAME_COUNT=R20	;счетчик кадров
	.def	PWM=R21		;счетчик ШИМ
	.def	STATUS=R23	;регистр флагов
	.def	MODE=R25	;режим работы

.cseg
.org 0
	RJMP 	START			;RESET
	RETI				;INT0
	RETI				;PCINT0
	RETI				;T0 OVERFLOW
	RETI				;EE RDY
	RETI				;COMP
	RJMP	NEXT_FRAME		;T0=A
	RETI				;T0=B
	RETI				;WDG
	RJMP	ADC_RD			;ADC
.org 0x000A
START:	
	CLR	ZERO			;ZERO=0
	OUTI	CLKPR,(1<<CLKPCE)	;сброс делителя тактовой
	OUT	CLKPR,ZERO
	OUTI	MCUCR,(1<<SE)		;вкл. Sleep
	OUTI	SPL,low(ramend)		;уст. стека
	OUTI	DDRB,0x00		;все порты - входы
	OUTI	PORTB,0x00		;
	OUTI	TCCR0A,(1<<WGM01)	;настройка таймера
	OUTI	TCCR0B,(1<<CS02)|(1<<CS00);
	OUTI	OCR0A,0xD0		;
	OUTI	TIMSK0,(1<<OCIE0A)	;
	OUTI	ADCSRA,(1<<ADEN)|(1<<ADIE)|(1<<ADSC)|(1<<ADPS2)|(1<<ADPS0) ;вкл. ADC
	OUTI	ADMUX,(1<<ADLAR)|(1<<MUX1)				;вход ADC1
	OUTI	ACSR,(1<<ACD)		;откл. компаратор
	CLR	STATUS			;сброс STATUS регистра
	CLR	FRAME_COUNT		;сброс счетуика кадров
	CLR	PWM			;сброс счетчика ШИМ
	CLR	XH			;установка указателя на 1й канал
	LDI	XL,1			;
	RCALL	LOAD_FRAME		;загружаем первый кадр
	SEI				;вкл. прерывания
	SLEEP				;спать
	CLR	MODE			;режим по умолчанию
LOOP0:	CJEQ	MODE,0,LOOP0		;ждем проверки режима
LOOP:	
	SLEEP				;спать
	SBRC	STATUS,0		;проверяем необходимость
	RCALL	LOAD_FRAME		;грузить новый кадр
	SBRC	STATUS,1		;проверяем необходимость
	RCALL	P_OUT			;обновить порты
	RJMP	LOOP			;зацикливание
P_OUT:
	CBR	STATUS,0x02		;сброс бита обновления портов
	LDI	R17,13			;константа для отключения канала (канал №13)
	LD	R18,X			;загружаем яркость
	ANDI	R18,0x07		;только 3 бита
	CP	PWM,R18			;сравниваем с ШИМ
	BRGE	SETBIT			;если меньше, не включаем канал
	MOV	R17,XL			;если больше загружаем константу для включения
SETBIT:
	LDI	ZH,High(PX*2-1)		;вычисляем конфигурацию PORT\DDR
	LDI	ZL,Low(PX*2-1)		;для текущего канала
	ADD	ZL,R17			
	ADC	ZH,ZERO
	LPM	R16,Z+			;загружаем DDR и PORT
	MOV	R17,R16			;
	SWAP	R17			;DDR - low, PORT - High
	ANDI	R16,0x0F		;
	ANDI	R17,0x0F
	OUT	DDRB,R17		;выставляем DDR и PORT
	OUT	PORTB,R16
	INC	XL			;канал+1
	CJNE	XL,13,P_RET		;проверяем что N канала не превышен
	LDI	XL,1
	INC	PWM			;увеличиваем счетчик ШИМ
	ANDI	PWM,0x07		;ШИМ 3 бита!
P_RET:
	RET				;возврат в главный цикл
ADC_RD:					;чтение АЦП
	SBI	ADCSRA,ADSC		;проверяем режим при старте
	SBR	STATUS,0x02		;
	IN	YL,ADCH			;читаем ADC
	CJNE	MODE,0,ADC_1		;проверяем режим, если<>0 - сохраняем в OCR и выходим
	CJNE	YL,0xFF,ADC_2		;если<>0, и ADC=MAX -> режим 2
	LDI	YL,0x80
	LDI	MODE,3			;режим 3 (бегущий огонь)
	RJMP	ADC_1			;
ADC_2:	CPI	YL,0x00			;ADC=0 -> режим 2
	LDI	YL,0x80			;иначе режим=1
	BRNE	ADC_0
	LDI	MODE,2			;ADC=0: режим 2 (индикатор уровня)
	RJMP	ADC_1
ADC_0:	LDI	MODE,1			;0<ADC<255: режим 1 (сосулька)
ADC_1:	OUT	OCR0A,YL		;устанавливаем скорость вывода кадров
	RETI				;выход
NEXT_FRAME:				;вывод кадра
	IN	STR,SREG		;сохраняем SREG
	INC	FRAME_COUNT		;увеличиваем
	CJNE	FRAME_COUNT,79,NEW_FRAME;счетчик кажров
	LDI	FRAME_COUNT,0		;по циклу 0-79
NEW_FRAME:
	SBR	STATUS,0x01		;устанавливаем флаг необходимости обновить кадр
NF_OUT:	OUT	SREG,STR		;
	RETI				;возврат
LOAD_FRAME:
	CBR	STATUS,0x01		;сбрасываем флаг
	CJEQ	MODE,1,SOS		;проверяем режим работы MODE, =1 -> грузим следующий кадр
	CJNE	MODE,2,MODE3		;=2 -> преобразование АЦП в индикатор уровня, =3 -> бегущий огонь
	LDI	ZH,0			;загружаем адрес первого канала
	LDI	ZL,1
	MOV	R16,YL			;копируем значение АЦП в R16
	LSR	R16			;делим на 4
	LSR	R16
CYC1:	CLR	R17			;вычисляем значение ШИМ для каждого из каналов
	CJEQ	R16,0,STR_RX		;в зависимости
	SUBI	R16,5			;от значения АЦП
	BRCS	XX1			;методом последовательного
	LDI	R17,7			;вычитания
	RJMP	STR_RX			;"яркости" из значения АЦП
XX1:	SUBI	R16,-5			;и разспределения ее
	MOV	R17,R16			;по каналам
	CLR	R16			;начиная с 1
	SUBI	R17,-2			;
STR_RX:	ST	Z+,R17			;
	CJNE	ZL,13,CYC1		;
	RET				;возврат
MODE3:
	INC	R1			;режим 3
	MOV	R2,R1			;бегущий огонь
	DEC	R2			;увеличиваем яркость канала 1
	MOV	R3,R2			;копируем значение в следующий канал
	DEC	R3			;уменьшаем значение
	MOV	R4,R3			;повторяем до 12 канала
	DEC	R4
	MOV	R5,R4
	DEC	R5
	MOV	R6,R5
	DEC	R6
	MOV	R7,R6
	DEC	R7
	MOV	R8,R7
	DEC	R8
	MOV	R9,R8
	DEC	R9
	MOV	R10,R9
	DEC	R10
	MOV	R11,R10
	DEC	R11
	MOV	R12,R11
	DEC	R12
	RET				;выход
SOS:	MOV	R17,FRAME_COUNT		;копируем счетчик кадров в R17
	CLR	R16			;вычисляем адрес кадра во флеш памяти
	LSL	R17			;смещение=номер кадра*6
	ROL	R16			;
	LSL	R17
	ROL	R16
	ADD	R17,FRAME_COUNT		
	ADC	R16,ZERO
	ADD	R17,FRAME_COUNT
	ADC	R16,ZERO
	LDI	ZH,High(FRAME*2)	;Z=(Frame*2)+FC*6
	LDI	ZL,Low(FRAME*2)
	ADD	ZL,R17			;прибавляем смещение
	ADC	ZH,R16
	LPM	R1,Z+			;читаем первый байт кадра
	MOV	R2,R1			;сохраняем в каналы 1 и 2
	SWAP	R1			;для 1-го - старшие 4 бита
	LPM	R3,Z+			;повторяем для каналов
	MOV	R4,R3			;3-4
	SWAP	R3			;
	LPM	R5,Z+			;5-6
	MOV	R6,R5			;
	SWAP	R5			;
	LPM	R7,Z+			;7-8
	MOV	R8,R7			;
	SWAP	R7			;
	LPM	R9,Z+			;9-10
	MOV	R10,R9			;
	SWAP	R9			;
	LPM	R11,Z+			;11-12
	MOV	R12,R11			;
	SWAP	R11			;
LF_RET:	RET				;возврат
PX:	.db	0x31,0x32,0x62,0x64,0xC4,0xC8,0x98,0x91,0x51,0x54,0xA2,0xA8,0x00,0x00	;данные PORT\DDR для каналов +"выкл все №13"
		;1 2  3 4  5 6  7 8 9 10 11 12 --   --
Frame:	
	.db	0x00,0x00,0x00,0x00,0x00,0x00	;0.5s	;кадры для последовательного вывода "тающей сосульки"
	.db	0x10,0x00,0x00,0x00,0x00,0x00	;1
	.db	0x20,0x00,0x00,0x00,0x00,0x00	;2
	.db	0x30,0x00,0x00,0x00,0x00,0x00	;3
	.db	0x40,0x00,0x00,0x00,0x00,0x00	;4
	.db	0x50,0x00,0x00,0x00,0x00,0x00	;5
	.db	0x60,0x00,0x00,0x00,0x00,0x00	;6
	.db	0x70,0x00,0x00,0x00,0x00,0x00	;7
	.db	0x71,0x00,0x00,0x00,0x00,0x00	;8
	.db	0x72,0x00,0x00,0x00,0x00,0x00	;9
	.db	0x73,0x00,0x00,0x00,0x00,0x00	;10
	.db	0x64,0x00,0x00,0x00,0x00,0x00	;11
	.db	0x65,0x00,0x00,0x00,0x00,0x00	;12
	.db	0x56,0x00,0x00,0x00,0x00,0x00	;13
	.db	0x57,0x00,0x00,0x00,0x00,0x00	;14
	.db	0x47,0x00,0x00,0x00,0x00,0x00	;15
	.db	0x47,0x00,0x00,0x00,0x00,0x00	;16
	.db	0x37,0x10,0x00,0x00,0x00,0x00	;17
	.db	0x37,0x20,0x00,0x00,0x00,0x00	;18
	.db	0x27,0x30,0x00,0x00,0x00,0x00	;19
	.db	0x26,0x40,0x00,0x00,0x00,0x00	;20
	.db	0x16,0x50,0x00,0x00,0x00,0x00	;21
	.db	0x15,0x60,0x00,0x00,0x00,0x00	;22
	.db	0x05,0x70,0x00,0x00,0x00,0x00	;23
	.db	0x04,0x71,0x00,0x00,0x00,0x00	;24
	.db	0x03,0x72,0x00,0x00,0x00,0x00	;25
	.db	0x02,0x63,0x00,0x00,0x00,0x00	;26
	.db	0x01,0x54,0x00,0x00,0x00,0x00	;27
	.db	0x00,0x45,0x10,0x00,0x00,0x00	;28
	.db	0x00,0x36,0x20,0x00,0x00,0x00	;29
	.db	0x00,0x27,0x30,0x00,0x00,0x00	;30
	.db	0x00,0x17,0x41,0x00,0x00,0x00	;31
	.db	0x00,0x06,0x52,0x00,0x00,0x00	;32
	.db	0x00,0x05,0x63,0x10,0x00,0x00	;33
	.db	0x00,0x04,0x74,0x20,0x00,0x00	;34
	.db	0x00,0x03,0x65,0x31,0x00,0x00	;35
	.db	0x00,0x02,0x56,0x42,0x00,0x00	;36
	.db	0x00,0x01,0x47,0x53,0x10,0x00	;37
	.db	0x00,0x00,0x36,0x64,0x21,0x00	;38
	.db	0x00,0x00,0x25,0x75,0x42,0x10	;39
	.db	0x00,0x00,0x14,0x66,0x54,0x31	;40
	.db	0x00,0x00,0x03,0x57,0x65,0x43	;41
	.db	0x00,0x00,0x02,0x46,0x76,0x55	;42
	.db	0x00,0x00,0x01,0x35,0x67,0x66	;43
	.db	0x00,0x00,0x00,0x24,0x56,0x77	;44
	.db	0x00,0x00,0x00,0x12,0x35,0x67	;45
	.db	0x00,0x00,0x00,0x01,0x23,0x47	;46
	.db	0x00,0x00,0x00,0x00,0x12,0x37	;47
	.db	0x00,0x00,0x00,0x00,0x01,0x26	;48
	.db	0x00,0x00,0x00,0x00,0x00,0x16	;49
	.db	0x00,0x00,0x00,0x00,0x00,0x06	;50
	.db	0x00,0x00,0x00,0x00,0x00,0x05	;51
	.db	0x00,0x00,0x00,0x00,0x00,0x05	;52
	.db	0x00,0x00,0x00,0x00,0x00,0x05	;53
	.db	0x00,0x00,0x00,0x00,0x00,0x04	;54
	.db	0x00,0x00,0x00,0x00,0x00,0x04	;55
	.db	0x00,0x00,0x00,0x00,0x00,0x04	;56
	.db	0x00,0x00,0x00,0x00,0x00,0x03	;57
	.db	0x00,0x00,0x00,0x00,0x00,0x03	;58
	.db	0x00,0x00,0x00,0x00,0x00,0x03	;59
	.db	0x00,0x00,0x00,0x00,0x00,0x02	;60
	.db	0x00,0x00,0x00,0x00,0x00,0x02	;61
	.db	0x00,0x00,0x00,0x00,0x00,0x02	;62
	.db	0x00,0x00,0x00,0x00,0x00,0x01	;63
	.db	0x00,0x00,0x00,0x00,0x00,0x01	;64
	.db	0x00,0x00,0x00,0x00,0x00,0x01	;65
	.db	0x00,0x00,0x00,0x00,0x00,0x00	;66
	.db	0x00,0x00,0x00,0x00,0x00,0x00	;67
	.db	0x00,0x00,0x00,0x00,0x00,0x00	;68
	.db	0x00,0x00,0x00,0x00,0x00,0x00	;69
	.db	0x00,0x00,0x00,0x00,0x00,0x00	;70
	.db	0x00,0x00,0x00,0x00,0x00,0x00	;71
	.db	0x00,0x00,0x00,0x00,0x00,0x00	;72
	.db	0x00,0x00,0x00,0x00,0x00,0x00	;73
	.db	0x00,0x00,0x00,0x00,0x00,0x00	;74
	.db	0x00,0x00,0x00,0x00,0x00,0x00	;75
	.db	0x00,0x00,0x00,0x00,0x00,0x00	;76
	.db	0x00,0x00,0x00,0x00,0x00,0x00	;77
	.db	0x00,0x00,0x00,0x00,0x00,0x00	;78
	.db	0x00,0x00,0x00,0x00,0x00,0x00	;79
Возможно вам помогут другие авторы, отписавшиеся в теме со своими прошивками и схемами...

Re: Светодиодная сосулька - индикатор уровня

Добавлено: Ср апр 11, 2018 23:19:33
Космо
Подскажите, а схемку с деталями не дадите ?

Re: Светодиодная сосулька - индикатор уровня

Добавлено: Чт апр 12, 2018 10:11:09
marksimo
Все хорошо, но яркость мала, пробовал разные светодиоды...

Re: Светодиодная сосулька - индикатор уровня

Добавлено: Чт апр 12, 2018 16:55:21
Engineer_Keen
Максимальной яркости с такой схемой не получить, ведь светодиоды горят поочереди, а увеличивать ток в импульсе не даст нагрузочная способность порта контроллера.

Re: Светодиодная сосулька - индикатор уровня

Добавлено: Чт дек 27, 2018 01:49:12
koala
Вариант "корпуса" сосульки на 20 ледов. Схема с 5 страницы уважаемого uk8amk. Печатная плата только под мс с обвязкой и кнопкой ресета. Диоды распаяны тонким проводом в лаковой изоляции. (из катушки от реле)
Плата и косичка с диодами помещена в прозрачную термоусадку. При запаивании торцов трубка вполне подходит для размещения на улице. Приспособление для быстроты сборки. На дощечке просверлены отверстия под диоды через 20 мм. Провод не зачищая наматывается (2-3 витка) на обрезанные выводы диодов (3-5 мм) и пропаивается, при этом в месте пайки лак сгорает. В таком варианте сосулька хорошо видна со всех сторон. Про матовые диоды уже писали, прозрачные диоды легко матируются наждачной бумагой.

Re: Светодиодная сосулька - индикатор уровня

Добавлено: Пн май 18, 2020 12:10:42
kret_a_v
приветствую всех
заинтересовал данный проект в качестве указателя поворотов на 20 светодиодах, для самодельного электросамоката (предполагается установка одной сосульки на каждый поворот)
есть пару вопросов
1 - как можно увеличить скорость пробега светящейся волны (к примеру цикл = 1 сек. и цикл = 0,5 сек) ? (если для этого нужна другая прошивка , помогите пожалуйста с модификацией)
2 - можно ли сделать эффект полного заполнения с последующим полным затуханием ? , (к примеру цикл = 1 сек. и цикл = 0,5 сек) (если для этого нужна другая прошивка , помогите пожалуйста с модификацией)
3 - можно ли использовать красные и желтые светодиоды для реализации режимов поворотов и сигнала стоп на одной плате , (предполагается установка одной сосульки на каждый поворот), при включении одного из поворотов работает одна из плат, при стопе включаются одновременно обе платы , понимаю что они должны быть синхронизированны между собой , как это выполнить схемно ? и если нужна другая прошивка прошу помочь с модификацией

*прим. понимаю что под мои реализации возможны 4 модификации прошивки
1 - цикл 0,5 сек
2 - цикл 1 сек
3 - полное заполнение 0,5 сек
4 - полное заполнение 1 сек
5 - совместная синхронная красная с раздельными желтыми

** прим - поворот запускается путем подачи питания на одну из плат , стоп запускается подачей питания на обе платы

заранее благодарен :beer: всем откликнувшимся

Re: Светодиодная сосулька - индикатор уровня

Добавлено: Вт май 26, 2020 15:46:05
kret_a_v
люди... есть кто то живой ?

Re: Светодиодная сосулька - индикатор уровня

Добавлено: Вт май 26, 2020 16:58:24
marksimo
Могу предложить TM1808, не помню, 50 или 100 шт. есть..
Специализированная микросхема - 12-ти канальный Led драйвер, готовый метеор...
купил в свое время, но так руки и не дошли..
вот схема:

Изображение

Re: Светодиодная сосулька - индикатор уровня

Добавлено: Вт май 26, 2020 17:58:08
Engineer_Keen
1 и 2е, можно, но нужно изменять прошивку. 3е, нельзя, если использовать один контроллер, из-за специфической системы соединения светодиодов. Если разводить две независимые схемы на одной плате, то так конечно можно.

Re: Светодиодная сосулька - индикатор уровня

Добавлено: Вт май 26, 2020 23:03:46
kret_a_v
Спасибо за ответ, помогите с прошивкой?
TM1808 у нас купить негде , кроме али

Re: Светодиодная сосулька - индикатор уровня

Добавлено: Ср май 27, 2020 00:17:18
marksimo
[uquote="kret_a_v",url="/forum/viewtopic.php?p=3846684#p3846684"]...
TM1808 у нас купить негде , кроме али[/uquote]

Так я же и говорю, у меня много есть..

Re: Светодиодная сосулька - индикатор уровня

Добавлено: Ср май 27, 2020 06:57:29
kret_a_v
Она от 220в питается? Мне от 5 вольт питание нужно,
и по чем они у вас ?

Re: Светодиодная сосулька - индикатор уровня

Добавлено: Вт июн 02, 2020 09:22:19
kret_a_v
помогите пожалуйста с прошивками
1 - время цикла 0,5 сек
2 - время цикла 1 сек
ув. Engineer_Keen можете помочь с прошивками ?

Re: Светодиодная сосулька - индикатор уровня

Добавлено: Вт июн 02, 2020 10:47:21
marksimo
TM1808 - 80 руб. - 1 шт.

Re: Светодиодная сосулька - индикатор уровня

Добавлено: Вт июн 02, 2020 13:01:20
Serzh2000
помогите пожалуйста с прошивками
а какая схема подключения , сколько светодиодов нужно , неужели все 20 шт. ? и как провода вести от одного контролера на 40 светодиодов? если на каждую сторону свой контролер, то аварийка будет мигать с разной частотой.

а вообще может посмотреть в сторону ws2812 ?! всего три проводка +-out! например вот https://autofeel.ru/tyuning/2017/06/03/ ... bilya.html

Re: Светодиодная сосулька - индикатор уровня

Добавлено: Вт июн 02, 2020 13:12:13
kret_a_v
планировал так (плату приложил) , если не потянет в разрыв перемычек воткну ключи

по вашей ссылке для меня слишком мудрено , так по проще будет :oops:
Часовой пояс: UTC+03:00
Страница 12 из 13

Создано на основе phpBB® Forum Software © phpBB Limited

Русская поддержка phpBB