Ассемблер (ASM) для AVR в вопросах и ответах
а с чего это он должен проверять? константа имеет допустимое для STS значение... просто данные тулишь в какую-то ячейку памяти.
- Реклама
А, да, это я туплю
а уже компилятор заподозрил
Надо было все-таки все макросами писать
а уже компилятор заподозрил
Надо было все-таки все макросами писать
можно и STS, но с другим адресом, естественноANALOG писал(а): TIMSK = 0x39, что меньше, чем 0x3F, так что тут нужен out
если рассматривать человека снизу, покажется, что мозг у него глубоко в жопе
при взгляде на многих сверху ничего не меняется...
Мой уютный бложик... заходите!
при взгляде на многих сверху ничего не меняется...
Мой уютный бложик... заходите!
Здравствуйте.
Изучаю АЦП, камень - ATmega88PA. К 0-евому каналу подключаю переменник.
Сам код:
Сначала программа не хотела работать как надо - не реагировала на байты с компьютера, начал дебажить, выяснилось, что процессор даже не заходит в обработчик прерывания по приему, т.к. светодиод не загорался (или загорался и очень быстро гас - тут я не уверен); код зажжения светодида в обработчике в данный момент убрал.
По итогу, добавил после метки Main две строчки
и всё заработало - байты принимаются и обрабатываются. АЦП работает и шлет показания.
И такой вопрос: почему без делея не работает?
Изучаю АЦП, камень - ATmega88PA. К 0-евому каналу подключаю переменник.
Сам код:
Спойлер
Код: Выделить всё
.include "m88PAdef.inc" ; Используем ATmega88PA
.include "macrobaselib.inc" ; Макроопределения
;======== RAM ============
.DSEG ; Сегмент ОЗУ
StrPtr: .byte 2
UCSR0B_temp: .byte 1
.equ MAXBUFF_IN = 10 ; Размер в байтах
.equ MAXBUFF_OUT = 10
IN_buff: .byte MAXBUFF_IN ; Буфер приема
IN_PTR_S: .byte 1 ; Указатель начала
IN_PTR_E: .byte 1 ; Указатель конца
IN_FULL: .byte 1 ; Флаг переполнения
OUT_buff: .byte MAXBUFF_OUT ; Буфер передачи
OUT_PTR_S: .byte 1 ; Указатель начала
OUT_PTR_E: .byte 1 ; Указатель конца
OUT_FULL: .byte 1 ; Флаг переполнения.
ADC_state: .byte 1 ;Состояние АЦП (вкл/выкл)
RX_sel: .byte 1 ;Переменная состояния отправки данных
ADCH_sel: .byte 1 ;Переменная текущего канала АЦП
ADCCH: .byte 8 ;Восемь байт под хранение результатов АЦП. По байту на канал.
;======= FLASH ===========
.CSEG ; Кодовый сегмент
.ORG 0x0000 ; (RESET)
RJMP Reset
.include "ivectors.inc" // Подключим файл с таблицой прерываний
;----------------------------------------------------------------------
; Это обработчик прерывания. Тут, на просторе, можно наворотить сколько
; угодно кода.
RX_OK:
PUSHF ; Макрос, пихающий в стек SREG и R16
PUSH R17
PUSH R18
PUSH XL
PUSH XH
LDI XL,low(IN_buff) ; Берем адрес начала буффера
LDI XH,high(IN_buff)
LDS R16,IN_PTR_E ; Берем смещение точки записи
LDS R18,IN_PTR_S ; Берем смещение точки чтения
ADD XL,R16 ; Сложением адреса со смещением
CLR R17 ; получаем адрес точки записи
ADC XH,R17
LDS R17,UDR0 ; Забираем данные
ST X,R17 ; сохраняем их в кольцо
INC R16 ; Увеличиваем смещение
CPI R16,MAXBUFF_IN ; Если достигли конца
BRNE NoEnd
CLR R16 ; переставляем на начало
NoEnd:
CP R16,R18 ; Дошли до непрочитанных данных?
BRNE RX_OUT ; Если нет, то просто выходим
RX_FULL:
LDI R18,1 ; Если да, то буффер переполнен.
STS IN_FULL,R18 ; Записываем флаг наполненности
RX_OUT:
STS IN_PTR_E,R16 ; Сохраняем смещение. Выходим
POP XH
POP XL
POP R18
POP R17
POPF ; Достаем SREG и R16
RETI
;***********************************
TX_OK:
RETI
;***********************************
UD_OK:
PUSHF ; Пихаем в стек SPEG, R16, R17, R18, R19
PUSH R17 ; и пару XL:XH
PUSH R18
PUSH R19
PUSH XL
PUSH XH
LDI XL,low(OUT_buff) ; Берем адрес начала буффера
LDI XH,high(OUT_buff)
LDS R16,OUT_PTR_E ; Берем смещение точки записи
LDS R18,OUT_PTR_S ; Берем смещение точки чтения
LDS R19,OUT_FULL ; Берем флаг переполнения
CPI R19,1 ; Если буффер переполнен, то указатель начала
BREQ NeedSend ; Равен указателю конца. Это надо учесть.
CP R18,R16 ; Указатель чтения достиг указателя записи?
BRNE NeedSend ; Нет! Буффер не пуст. Надо слать дальше
LDI R16,(1<<RXEN0)|(1<<TXEN0)|(1<<RXCIE0)|(1<<TXCIE0)|(0<<UDRIE0)
STS UCSR0B, R16 ; Запрет прерывания По пустому UDR
RJMP TX_OUT ; Выходим
NeedSend:
CLR R17 ; Получаем ноль
STS OUT_FULL,R17 ; Сбрасываем флаг переполнения
ADD XL,R18 ; Сложением адреса со смещением
ADC XH,R17 ; получаем адрес точки чтения
LD R17,X ; Берем байт из буффера
STS UDR0,R17 ; Отправляем его в USART
INC R18 ; Увеличиваем смещение указателя чтения
CPI R18,MAXBUFF_OUT ; Достигли конца кольца?
BRNE TX_OUT ; Нет?
CLR R18 ; Да? Сбрасываем, переставляя на 0
TX_OUT:
STS OUT_PTR_S,R18 ; Сохраняем указатель
POP XH
POP XL
POP R19
POP R18
POP R17
POPF ; Выходим, достав все из стека
RETI
;**************************************
ADC_OK:
PUSHF
PUSH ZL
PUSH ZH
PUSH R17
LDS R16,ADMUX ;Берем ADMUX
ANDI R16,0b0001111 ;Маской отрезаем лишние биты. Получаем номер канала
;С которого было снято измерение.
;MOV R17,R16 ; Cохранили копию номера канала
LDI ZL,low(ADCCH) ; Берем адрес начала массива с будущими данными.
LDI ZH,High(ADCCH)
ADD ZL,R16 ; Прибавляем к адресу наш номер канала.
; Если было переполнение, то будет флаг С
CLR R16 ; Флаг важен, а значение в R16 уже нет. Но нам нужен ноль
; Возьмем и сделаем его из R16.
ADC ZH,R16 ; Сложим флаг возможного переполнения с ZH
; Т.о. у нас получается в Z = адрес (ADCCH+номер канала)
; И значения из разных каналов ложатся в разные переменные массива
; с адресом базы ADCCH
LDS R16,ADCL ; Младшее значение нам не надо. Но считать его нужно.
LDS R16,ADCH ; Берем в R16 значение из АЦП
ST Z,R16 ; Сохраняем его в массив по нужному адресу
/*
LDS R16,ADMUX ; Опять взяли ADMUX
ANDI R16,0xF8 ; На этот раз обнулили номер канала. Оставив остальные биты нетронутыми
INC R17 ; Увеличили на 1 заныченный ранее номер канала
ANDI R17,0x07 ; Обрезали лишние биты, чтобы не было переполнения.
; Число по маске 0х07 в принципе не может быть больше 7.
; А каналов у нас от 0 до 7. То что надо.
OR R16,R17 ; Слепили старое значение из ADMUX c новым значением номера
OUT ADMUX,R16 ; Канала. Т.е. по факту сделали MUX = MUX+1 выбрав следующий канал
; Спихнули его в регистр ADMUX. Все, следующий канал выбран. Можно запускать
; Следующее преобразование. */
OUTI ADCSRA,(1<<ADEN)|(1<<ADIE)|(1<<ADSC)|(0<<ADATE)|(3<<ADPS0) ; Запустили
POP R17 ; Корректный выход из прерывания.
POP ZH
POP ZL
POPF
RETI
;----------------------------------------------------------------------
// Теперь инициализируем всё, что нам нужно.
Reset:
STACKINIT // Инициализация стека
RAMFLUSH // Очистка ОЗУ
GPRFLUSH // Очистка РОН (Регистров Общего Назначения)
.equ XTAL = 16000000
.equ baudrate = 9600
.equ bauddivider = XTAL/(16*baudrate)-1
//Инициализация USART
LDI R16, low(bauddivider) ;Записываем в UBRR0H:UBRR0L
STS UBRR0L,R16 ;делитель для настройки скорости передачи
LDI R16, high(bauddivider)
STS UBRR0H,R16
LDI R16, 0
STS UCSR0A, R16
; Прерывания прием-передачи разрешены, прием-передача разрешена
LDI R16, (1<<RXEN0)|(1<<TXEN0)|(1<<RXCIE0)|(1<<TXCIE0)|(0<<UDRIE0)
STS UCSR0B, R16
; Формат кадра - 8 бит
LDI R16, (1<<UCSZ00)|(1<<UCSZ01)
STS UCSR0C, R16
//Инициализация АЦП
OUTI ADMUX,(1<<REFS0)|(1<<ADLAR)|(0<<MUX0)
;Опорное напряжение с AVCC, выравнивание влево, канал 0.
//Мигание светодиодом для зрительного контроля рестарта микроконтроллера
OUTI DDRB, 0b11111101 //Инициализация порта B, PB0 - на выход
RCALL LED_flashing
SEI // Глобально разрешаем прерывания
Main:
rcall Delay
rcall Delay
RCALL Buff_Pop ; Вызываем подпрограмму чтения из буфера приема USART
; В R19 - код ошибки (1 - пустой буфер), R17 - данные.
CPI R19, 1 ; Проверяем, пустой ли буфер.
BREQ M1 ; Если буфер пуст, то идем на М1.
RCALL Processing_of_external_commands
; Процедура обработки команд, принимаемых по USART
M1:
LDS R16, ADC_state
SBRS R16, 0 ; Если АЦП запущен, то с него нужно отправить данные по USART
rjmp M2 ; А если не запущен, то идем дальше
LDS R19, ADCCH ; Берем данные с 0-ого канала АЦП
RCALL Buff_Push ; Кладем их в буфер
LDI R16,(1<<RXEN0)|(1<<TXEN0)|(1<<RXCIE0)|(1<<TXCIE0)|(1<<UDRIE0)
STS UCSR0B, R16 ; Разрешаем прерывания По пустому UDR
M2:
rjmp Main
/*-------------------------------------
| Начало сектора подпрограмм и функций |
-------------------------------------*/
;--------------Подпрограмма обработки команд внешнего управления-------*
Processing_of_external_commands:
cpi R17, '0' ;Сравниваем R17 с нулем
BREQ I1 ;Если пришел нуль, то гасим светодиод
cpi R17, '1' ;Сравниваем R17 с единицей
BREQ I2 ;Если пришла единица - зажигаем
cpi R17, 'G' ;Сравниваем R17 c 'G'
BREQ I3 ;Запускаем АЦП - Go
cpi R17, 'S' ;Сравниваем R17 c 'S'
BREQ I4 ;Выключаем АЦП - Stop
rjmp Processing_of_external_commands_EXIT
I1:
cbi portb,0 ;Гасим светодиод
rjmp Processing_of_external_commands_EXIT
I2:
sbi portb,0 ;Зажигаем светодиод
rjmp Processing_of_external_commands_EXIT
I3:
cli
LDI R16, 0b00000001
STS ADC_state, R16
sei
OUTI ADCSRA,(1<<ADEN)|(1<<ADIE)|(1<<ADSC)|(0<<ADATE)|(3<<ADPS0)
rjmp Processing_of_external_commands_EXIT
I4:
cli
LDI R16, 0b00000000
STS ADC_state, R16
sei
OUTI ADCSRA,(0<<ADEN)|(0<<ADIE)|(0<<ADSC)|(0<<ADATE)|(3<<ADPS0)
Processing_of_external_commands_EXIT:
RET
;-----------------Конец подпрограммы-----------------------------------
;--------------Подпрограмма задержки [Delay]---------------------------*
Delay:
LDI R20,0
Loop:
dec R20
BRNE Loop
dec R21
BRNE Loop
ret
;-----------------Конец подпрограммы-----------------------------------
;--------Подпрограмма чтения из буфера USART---------------------------*
; OUT: R17 - Data,
; R19 - ERROR CODE
Buff_Pop:
LDS R16, UCSR0B ; Берем в R16 значение UCSR0B
STS UCSR0B_temp, R16 ; Сажаем предыдущее значение UCSR0B в ОЗУ
LDI R16, (0<<RXCIE0)|(0<<TXCIE0)|(0<<UDRIE0)
STS UCSR0B, R16 ; Запрещаем прерывания от UART
; для соблюдения атомарности.
LDI XL,low(IN_buff) ; Берем адрес начала буффера
LDI XH,high(IN_buff)
LDS R16,IN_PTR_E ; Берем смещение точки записи
LDS R18,IN_PTR_S ; Берем смещение точки чтения
LDS R19,IN_FULL ; Берм флаг переполнения
CPI R19,1 ; Если буффер переполнен, то указатель начала
BREQ NeedPop ; Равен указателю конца. Это надо учесть.
CP R18,R16 ; Указатель чтения достиг указателя записи?
BRNE NeedPop ; Нет! Буффер не пуст. Работаем дальше
LDI R19,1 ; Код ошибки - пустой буффер!
RJMP _TX_OUT ; Выходим
NeedPop:
CLR R17 ; Получаем ноль
STS IN_FULL,R17 ; Сбрасываем флаг переполнения
ADD XL,R18 ; Сложением адреса со смещением
ADC XH,R17 ; получаем адрес точки чтения
LD R17,X ; Берем байт из буффера
CLR R19 ; Сброс кода ошибки
INC R18 ; Увеличиваем смещение указателя чтения
CPI R18,MAXBUFF_OUT ; Достигли конца кольца?
BRNE _TX_OUT ; Нет?
CLR R18 ; Да? Сбрасываем, переставляя на 0
_TX_OUT:
STS IN_PTR_S,R18 ; Сохраняем указатель
LDS R16, UCSR0B_temp ;Загружаем в R16 предыдущее состояние UCSR0B
STS UCSR0B, R16 ;Возвращаем обратно прерывания по USART
RET
;-----------Конец подпрограммы-----------------------------------------
;--------Подпрограмма записи в буфер USART-----------------------------*
; IN R19 - DATA
; OUT R19 - ERROR CODE
Buff_Push:
PUSH ZL
PUSH ZH
LDS R16, UCSR0B ; Берем в R16 значение UCSR0B
STS UCSR0B_temp, R16 ; Сажаем предыдущее значение UCSR0B в ОЗУ
LDI R16, (0<<RXCIE0)|(0<<TXCIE0)|(0<<UDRIE0)
STS UCSR0B, R16 ; Запрещаем прерывания от UART
; для соблюдения атомарности.
LDI XL,low(OUT_buff) ; Берем адрес начала буффера
LDI XH,high(OUT_buff)
LDS R16,OUT_PTR_E ; Берем смещение точки записи
LDS R18,OUT_PTR_S ; Берем смещение точки чтения
ADD XL,R16 ; Сложением адреса со смещением
CLR R17 ; получаем адрес точки записи
ADC XH,R17
ST X,R19 ; сохраняем их в кольцо
CLR R19 ; Очищаем R19, теперь там код ошибки
; Который вернет подпрограмма
INC R16 ; Увеличиваем смещение
CPI R16,MAXBUFF_OUT ; Если достигли конца
BRNE _NoEnd
CLR R16 ; переставляем на начало
_NoEnd:
CP R16,R18 ; Дошли до непрочитанных данных?
BRNE _RX_OUT ; Если нет, то просто выходим
_RX_FULL:
LDI R19,1 ; Если да, то буффер переполнен.
STS OUT_FULL,R19 ; Записываем флаг наполненности
; В R19 остается 1 - код ошибки переполнения
_RX_OUT:
STS OUT_PTR_E,R16 ; Сохраняем смещение. Выходим
LDS R16, UCSR0B_temp ;Загружаем в R16 предыдущее состояние UCSR0B
STS UCSR0B, R16 ;Возвращаем обратно прерывания по USART
POP ZH
POP ZL
RET
;-----------Конец подпрограммы-----------------------------------------
;--------Подпрограмма стартового мигания светодиодом-------------------*
LED_flashing:
OUTI PORTB, 0b00000011 //Подтяжка на PB0 и PB1
rcall Delay
rcall Delay
OUTI PORTB, 0b00000010
rcall Delay
rcall Delay
OUTI PORTB, 0b00000011
rcall Delay
rcall Delay
OUTI PORTB, 0b00000010
rcall Delay
rcall Delay
OUTI PORTB, 0b00000011 //Подтяжка на PB0 и PB1
rcall Delay
rcall Delay
OUTI PORTB, 0b00000010
rcall Delay
rcall Delay
OUTI PORTB, 0b00000011
rcall Delay
rcall Delay
OUTI PORTB, 0b00000010
rcall Delay
rcall Delay
OUTI PORTB, 0b00000011 //Подтяжка на PB0 и PB1
rcall Delay
rcall Delay
OUTI PORTB, 0b00000010
rcall Delay
rcall Delay
OUTI PORTB, 0b00000011
rcall Delay
rcall Delay
OUTI PORTB, 0b00000010
rcall Delay
rcall Delay
RET
;-----------------Конец подпрограммы-----------------------------------
String: .db "23C ",0
;===== EEPROM ============
.ESEG ; Сегмент EEPROM (ППЗУ)
По итогу, добавил после метки Main две строчки
Код: Выделить всё
Main:
rcall Delay
rcall DelayИ такой вопрос: почему без делея не работает?
Привет, коты! На сей раз вопрос про АЦП. Гугл мне не очень помог, потому что все блоггерные умники, почему-тj напрочь влюблены в Си и пример на Ассемблере из быстро вылезающих сайтов мне ничего не попалось.
Вопрос у меня такой: как правильно пересчитать полученное значение их АЦП в напряжение?
Если я всё правильно понял, то формула такая:
(1.1* ADCH*4.03)/1024(или 1023?), где
1.1 - опорное U, берущееся внутри ATmega48
ADCH - то, что получилось с АЦП
4.03 - коэффициент делителя напряжения (10K и 3.3K)
1024 - выборки АЦП при 10битном АЦП (или нужно 1023?) Результат замера восьмибитный. 2 младших бита я не забираю.
Я думаю сделать так:
Меня смущают дробные числа. Они очень весело описываются любителями си в бесполезных туториалах, мол "у нас точность измерения 0.0024 В!". Но, насколько я помню, дробные константы просчитает компилятор. А при вычислениях в МК там, вроде бы, всё округлится? А как тогда получить напряжение, скажем 2.7 В? Или представлять это как 2700 мВ?
Все это делается с целью следить за разрядом батареи, от которой питается все устройство, чтобы не дать ей переразрядиться.
Все это спрашиваю тут, потому что имею опыт сидеть целый день и не зная, что на самом деле происходит в регистрах? ломать голову. Не хочу потратить кучу времени зря. Помогите его спасти
В принципе, куска программы с мало-мальскими комментариями, которая делает то, о чём я написал выше, будет достаточно. Я всё-таки хоть еще не радиокот, но я уже не радиокотёнок 
Вопрос у меня такой: как правильно пересчитать полученное значение их АЦП в напряжение?
Если я всё правильно понял, то формула такая:
(1.1* ADCH*4.03)/1024(или 1023?), где
1.1 - опорное U, берущееся внутри ATmega48
ADCH - то, что получилось с АЦП
4.03 - коэффициент делителя напряжения (10K и 3.3K)
1024 - выборки АЦП при 10битном АЦП (или нужно 1023?) Результат замера восьмибитный. 2 младших бита я не забираю.
Я думаю сделать так:
Код: Выделить всё
;Сначала
.equ ADCco=(1.1*4.03)/1024 ;Просчёт с константами
;Потом уже после завершения преобразования:
Mov R16,ADCH ;Загрузка результата АЦП в регистр
Ldi R17,ADCco ;Загрузка результата вычисления констант
FMUL R16,R17 ;Беззнаковое умножение дробных чиселВсе это делается с целью следить за разрядом батареи, от которой питается все устройство, чтобы не дать ей переразрядиться.
Все это спрашиваю тут, потому что имею опыт сидеть целый день и не зная, что на самом деле происходит в регистрах? ломать голову. Не хочу потратить кучу времени зря. Помогите его спасти
Почему я здесь и задаю тупые вопросы?
Потому что хочу научиться.
Потому что хочу научиться.
- Реклама
Если собираетесь юзать все 10 битов АЦП, то вам придется заморочиться с грамотной разводкой платы и работой АЦП со спящим процессором.
Курите даташит: стр.248 24.6 ADC Noise Canceler
Про разводку, обратите внимание на землю: http://hamradio.tomsk.ru/2013/04/14/пом ... стройства/
Курите даташит: стр.248 24.6 ADC Noise Canceler
Про разводку, обратите внимание на землю: http://hamradio.tomsk.ru/2013/04/14/пом ... стройства/
Mika, в ADCco будет ноль, т.к. деление на 1024 даст меньше 1 и в итоге все занулится
А так да, лучше считать в милливольтах.
Конкретно для вашей задачи, если нужно просто контролировать, не опустилось ли напряжение ниже определенного предела, то я бы сказал, лучше вообще не трогать значения с АЦП (не переводить их в вольты), а просто сравнивать с заранее обсчитанной константой
А так да, лучше считать в милливольтах.
Конкретно для вашей задачи, если нужно просто контролировать, не опустилось ли напряжение ниже определенного предела, то я бы сказал, лучше вообще не трогать значения с АЦП (не переводить их в вольты), а просто сравнивать с заранее обсчитанной константой
Если используешь 8 бит, то не 1024 надо использовать а константу 256 в формулах. Но и это не нужно - умножать, получать вольты средствами МК чтобы сравнить с константой - это лишняя работа, лучше константу привести к виду кода выходящего с АЦП - т.е. к целому числу 0..255 соответствующему нужному напряжению. Тогда эту константу посчитает компилятор, а контроллеру останется только сравнивать байт в регистре с константой - а это уже совершенно другой уровень математики.
Если же все-таки надо вывести куда-то значение напряжения в миливольтах, то делается такой ход конём - подбирается опорное напряжение, делитель на входе таким образом чтобы сдвинув(умножив результат измерения на 2-4-8-16-32) результат измерения получить целое число представляющее напряжение в кратных 10 единицах(1мв-10мв-100мв) - нолики можно дорисовать при выводе и запятую поставить в нужном месте...
Да, это целое потом при помощи BIN2BCD преобразования можно разложить на цифры и вывести как текст.
Если же все-таки надо вывести куда-то значение напряжения в миливольтах, то делается такой ход конём - подбирается опорное напряжение, делитель на входе таким образом чтобы сдвинув(умножив результат измерения на 2-4-8-16-32) результат измерения получить целое число представляющее напряжение в кратных 10 единицах(1мв-10мв-100мв) - нолики можно дорисовать при выводе и запятую поставить в нужном месте...
Да, это целое потом при помощи BIN2BCD преобразования можно разложить на цифры и вывести как текст.
- Сообщения: 758
- Зарегистрирован: Вс фев 10, 2013 15:26:00
Привет! Спасибо за кучу ответов
Вчера я правда чё-то не подумал о том, что надо просто посчитать заранее, какому значению в диапазоне 0...255 будет что соответствовать
Спасибо за ссылку на материал про помехи, щас обязательно ознакомлюсь. По поводу раскуривания ДШ и noise canceller - это я всё вчера смотрел, пока конфигурировал АЦП. Почти всё понял, но учитывая то, что моя задача не требует ни скорости ни точности,Ю сильно заострять внимание на этом не стал.
UPD:
Вот такое насчитал, если кому-то не лень, пробегитесь, может что-то напутал
Uref 1.1V = 255
Ubat 4.2V -> voltage devider ->1.05V
1.1V/255 = 0,0043137254901961
1.05/0,0043137254901961 = 243,4090909090897 = 243
4.2V-3.3V = 0.9V Рабочий диапазон
4.2V/0.9 = 4.6
243/4.6 = 53 - эквивалент 0.9V
243-53=190 - Минимально допустимое значение с АЦП
53/4 = 13.25 = 13 Шаг индикатора разряда ( - - - - )
243-230-217-204-191
*** *** *** *** Полная
___ *** *** *** 3/4
___ ___ *** *** 2/4
___ ___ ___ *** 1/4
Вот примерно так
UPD:
Вот такое насчитал, если кому-то не лень, пробегитесь, может что-то напутал
Uref 1.1V = 255
Ubat 4.2V -> voltage devider ->1.05V
1.1V/255 = 0,0043137254901961
1.05/0,0043137254901961 = 243,4090909090897 = 243
4.2V-3.3V = 0.9V Рабочий диапазон
4.2V/0.9 = 4.6
243/4.6 = 53 - эквивалент 0.9V
243-53=190 - Минимально допустимое значение с АЦП
53/4 = 13.25 = 13 Шаг индикатора разряда ( - - - - )
243-230-217-204-191
*** *** *** *** Полная
___ *** *** *** 3/4
___ ___ *** *** 2/4
___ ___ ___ *** 1/4
Вот примерно так
Почему я здесь и задаю тупые вопросы?
Потому что хочу научиться.
Потому что хочу научиться.
Я делал вольтметр для автомобиля и сильно не заморачивался по поводу вычислений.
Сделал простой делитель 20к - 1к(перем) - 1к. И подстроил переменный резистор так, чтобы при 25.5В напряжение на движке резистора было около 1.1В - то есть, при 8-битном преобразовании получалось (выравнивание ADLAR вправо) ADCL = 255.
Для вывода на семисегментник, таким образом, даже расчёты не нужны. Просто точку не забыть поставить во втором разряде.
Сделал простой делитель 20к - 1к(перем) - 1к. И подстроил переменный резистор так, чтобы при 25.5В напряжение на движке резистора было около 1.1В - то есть, при 8-битном преобразовании получалось (выравнивание ADLAR вправо) ADCL = 255.
Для вывода на семисегментник, таким образом, даже расчёты не нужны. Просто точку не забыть поставить во втором разряде.
- Сообщения: 24
- Зарегистрирован: Вс ноя 25, 2012 13:57:12
Помогите пожалуйста!!! Я сейчас начал изучать Таймеры и столкнулся с такой проблемой.
При настройке Таймер Т0 на Mega8 все что заношу (до 255)в регистр TCNT0, в результате не изменяеться частота мигание LED. Пожалуйста укажите на мою ошибку.
.include "m8Adef.inc" ; Присоединение файла описаний
.def temp = r16 ; Определение главного рабочего регистра
; RAM =================
.DSEG ; Сегмент ОЗУ
; FLASH ===============
.CSEG ; Кодовый сегмент
.org 0 ;Установка текущего адреса на ноль
;........ Переопределение векторов прерываний
start: rjmp reset ; Reset Handler ;Reset Переход на начало программы
reti ;EXT_INT0 ; IRQ0 Handler
reti ;EXT_INT1 ; IRQ1 Handler
reti ;TIM2_COMP ; Timer2 Compare Handler
reti ;TIM2_OVF ; Timer2 Overflow Handler
reti ;TIM1_CAPT ; Timer1 Capture Handler
reti ;TIM1_COMPA ; Timer1 CompareA Handler
reti ;TIM1_COMPB ; Timer1 CompareB Handler
reti ;TIM1_OVF ; Timer1 Overflow Handler
rjmp TIM0_OVF ; Timer0 Overflow Handler
reti ;SPI_STC ; SPI Transfer Complete Handler
reti ;USART_RXC ; USART RX Complete Handler
reti ;USART_UDRE ; UDR Empty Handler
reti ;USART_TXC ; USART TX Complete Handler
reti ;ADC ; ADC Conversion Complete Handler
reti ;EE_RDY ; EEPROM Ready Handler
reti ;ANA_COMP ; Analog Comparator Handler
reti ;TWSI ; Two-wire Serial Interface Handler
reti ;SPM_RDY ; Store Program Memory Ready Handler
;---------------------------Инициализация стека
reset: ldi r16,high(RAMEND) ; Main program start
out SPH,temp ; Set Stack Pointer to top of RAM
ldi r16,low(RAMEND)
out SPL,temp
;=======
;---------------------------Инициализация портов
ldi r17,(1<<4) ;
out DDRB, r17 ;Копирование из r17 в DDRB (РВ4 - выход)
;---------------------------Инициализация 8-разрядный таймер-счетчик 0 ВАРИАНТ №1
ldi r16, (1<<CS00)|(1<<CS02) ;Пределитель 1024
out TCCR0,r16 ;
ldi r16, (1<<TOIE0) ;бит 0 – TOIE0: Включение Прерывания Переполнения Таймер/Счетчика 0
out TIMSK,r16 ;
ldi r16, 0b11001000 ;11001000 =200,
out TCNT0,r16 ;начальное значение счетчика
sei ;Глобальное разрешение прерываний
;------------------------------------------------------------------------------------------------
;-------------------------- Основной цикл
;-------------------------- Начало основного цикла ВАРИАНТ №1
main:
rjmp main ; К началу цикла
;-------------------------- Преривания по Переполнение таймера-счетчика 0
TIM0_OVF:
;-------------------------------- Мигание светодиода
eor r18,r17 ;Исключающее ИЛИ регистров r16 и r17
out PORTB,r18 ;Копирование из r16 в PORTB
reti
; EEPROM ==============
.ESEG ; Сегмент EEPROM
При настройке Таймер Т0 на Mega8 все что заношу (до 255)в регистр TCNT0, в результате не изменяеться частота мигание LED. Пожалуйста укажите на мою ошибку.
Спойлер
;------------------------- Псевдокоманды управления.include "m8Adef.inc" ; Присоединение файла описаний
.def temp = r16 ; Определение главного рабочего регистра
; RAM =================
.DSEG ; Сегмент ОЗУ
; FLASH ===============
.CSEG ; Кодовый сегмент
.org 0 ;Установка текущего адреса на ноль
;........ Переопределение векторов прерываний
start: rjmp reset ; Reset Handler ;Reset Переход на начало программы
reti ;EXT_INT0 ; IRQ0 Handler
reti ;EXT_INT1 ; IRQ1 Handler
reti ;TIM2_COMP ; Timer2 Compare Handler
reti ;TIM2_OVF ; Timer2 Overflow Handler
reti ;TIM1_CAPT ; Timer1 Capture Handler
reti ;TIM1_COMPA ; Timer1 CompareA Handler
reti ;TIM1_COMPB ; Timer1 CompareB Handler
reti ;TIM1_OVF ; Timer1 Overflow Handler
rjmp TIM0_OVF ; Timer0 Overflow Handler
reti ;SPI_STC ; SPI Transfer Complete Handler
reti ;USART_RXC ; USART RX Complete Handler
reti ;USART_UDRE ; UDR Empty Handler
reti ;USART_TXC ; USART TX Complete Handler
reti ;ADC ; ADC Conversion Complete Handler
reti ;EE_RDY ; EEPROM Ready Handler
reti ;ANA_COMP ; Analog Comparator Handler
reti ;TWSI ; Two-wire Serial Interface Handler
reti ;SPM_RDY ; Store Program Memory Ready Handler
;---------------------------Инициализация стека
reset: ldi r16,high(RAMEND) ; Main program start
out SPH,temp ; Set Stack Pointer to top of RAM
ldi r16,low(RAMEND)
out SPL,temp
;=======
;---------------------------Инициализация портов
ldi r17,(1<<4) ;
out DDRB, r17 ;Копирование из r17 в DDRB (РВ4 - выход)
;---------------------------Инициализация 8-разрядный таймер-счетчик 0 ВАРИАНТ №1
ldi r16, (1<<CS00)|(1<<CS02) ;Пределитель 1024
out TCCR0,r16 ;
ldi r16, (1<<TOIE0) ;бит 0 – TOIE0: Включение Прерывания Переполнения Таймер/Счетчика 0
out TIMSK,r16 ;
ldi r16, 0b11001000 ;11001000 =200,
out TCNT0,r16 ;начальное значение счетчика
sei ;Глобальное разрешение прерываний
;------------------------------------------------------------------------------------------------
;-------------------------- Основной цикл
;-------------------------- Начало основного цикла ВАРИАНТ №1
main:
rjmp main ; К началу цикла
;-------------------------- Преривания по Переполнение таймера-счетчика 0
TIM0_OVF:
;-------------------------------- Мигание светодиода
eor r18,r17 ;Исключающее ИЛИ регистров r16 и r17
out PORTB,r18 ;Копирование из r16 в PORTB
reti
; EEPROM ==============
.ESEG ; Сегмент EEPROM
А почитать даташит? Ну, первую итерацию он у тебя отработал короче последующих и это все действие которое ты определил загрузкой значения в таймер. либо настраивать надо его в другой режим работы, где период таймера задаётся регистром сравнения, либо сбрасывать на указанное значение КАЖДОЕ переполнение таймера.
- Сообщения: 24
- Зарегистрирован: Вс ноя 25, 2012 13:57:12
Большое Спасибо, Ваши слова мне очень помогли!!! я добавил "начальное значение счетчика" в преривание. И все заработало !Alexeyslav писал(а):либо сбрасывать на указанное значение КАЖДОЕ переполнение таймера.
Я чувствовал что я что та не дописал, но не мог понять что именно. Спасибо еще раз. Буду дальше изучать таймеры.
Спойлер
TIM0_OVF:;-------------------------------- Мигание светодиода
ldi r16, 0b1100100 ;11001000 =200,
out TCNT0,r16 ;начальное значение счетчика
eor r18,r17 ;Исключающее ИЛИ регистров r16 и r17
out PORTB,r18 ;Копирование из r16 в PORTB
reti
Всем привет!
Вопрос такой, по выходу из подпрограммы.
Правильно ли я понимаю, в ходе выполнения подпррограммы programm, 2 команды Pop вынут из стека адрес возврата, который попал туда при выполнении команды rcall, что в свою очередь поставит на край стека содержимое R18, которое было туда положено в самом начале cycle_1. После чего мы кладём в стек адрес метки cycle_2 и по команде ret извлекаем оттуда этот адрес, переходим на cycle_2, а в стеке готовым к извлечению лежит то, что было в R18. Я ничего не упускаю?
И если всё так, то чтобы перейти по другому адресу из подпрограммы, и сохранить стек таким, каким он был до того, как мы попали в подпрограмму, можно просто дважды извлечь значения из стека, после чего сделав jmp или rjmp по метке?
Вопрос такой, по выходу из подпрограммы.
Код: Выделить всё
cycle_1:
Push R17
NOP;1
NOP;2
NOP;3
rcall programm
NOP;4
NOP;5
NOP;6
rjmp cycle_1
cycle_2:
NOP7
NOP8
NOP9
rjmp cycle_2
programm:
NOP
NOP
NOP
Pop R16
Pop R16
LDI 16,low(cycle_2)
Push R16
LDI 16,High(cycle_2)
Push R16
retИ если всё так, то чтобы перейти по другому адресу из подпрограммы, и сохранить стек таким, каким он был до того, как мы попали в подпрограмму, можно просто дважды извлечь значения из стека, после чего сделав jmp или rjmp по метке?
Почему я здесь и задаю тупые вопросы?
Потому что хочу научиться.
Потому что хочу научиться.
У тебя стек разрушится. У тебя постоянно с каждым циклом будет расти стек и когда он дойдет до начала памяти начнет затирать предыдущие значения.
Надо всегда держаться правила что на каждый PUSH должен быть свой POP, так же как на каждый CALL должен быть свой RET в пределах одного логического блока(внутри тела цикла, внутри тела условного оператора). Иначе путаницы и переполнения стека не избежать.
Надо всегда держаться правила что на каждый PUSH должен быть свой POP, так же как на каждый CALL должен быть свой RET в пределах одного логического блока(внутри тела цикла, внутри тела условного оператора). Иначе путаницы и переполнения стека не избежать.
А как понять разрушится?
Ведь в примере, который я написал, на каждый (условно) Push, есть Pop, смотрите:
cycle_1:
Push R17 PUSH НОМЕР 1
NOP;1
NOP;2
NOP;3
rcall programmPUSH НОМЕР 2 и 3
NOP;4
NOP;5
NOP;6
rjmp cycle_1
cycle_2:
NOP7
NOP8
NOP9
rjmp cycle_2
programm:
NOP
NOP
NOP
Pop R16POP для PUSH НОМЕР 2 и 3
Pop R16
LDI 16,low(cycle_2)
Push R16PUSH НОМЕР 4
LDI 16,High(cycle_2)
Push R16PUSH НОМЕР 5
retPOP для PUSH НОМЕР 4 и 5
И по выходу у нас на готове в стеке байт для Pop для Push номер 1.
P.S. Не выделил код тегом, чтобы жирным выделить комменты
И да, я, видимо, неудачно выразился с циклами. Я тут подразумеваю рассмотрение при однократном проходе программы до команды ret.
Ведь в примере, который я написал, на каждый (условно) Push, есть Pop, смотрите:
cycle_1:
Push R17 PUSH НОМЕР 1
NOP;1
NOP;2
NOP;3
rcall programmPUSH НОМЕР 2 и 3
NOP;4
NOP;5
NOP;6
rjmp cycle_1
cycle_2:
NOP7
NOP8
NOP9
rjmp cycle_2
programm:
NOP
NOP
NOP
Pop R16POP для PUSH НОМЕР 2 и 3
Pop R16
LDI 16,low(cycle_2)
Push R16PUSH НОМЕР 4
LDI 16,High(cycle_2)
Push R16PUSH НОМЕР 5
retPOP для PUSH НОМЕР 4 и 5
И по выходу у нас на готове в стеке байт для Pop для Push номер 1.
P.S. Не выделил код тегом, чтобы жирным выделить комменты
И да, я, видимо, неудачно выразился с циклами. Я тут подразумеваю рассмотрение при однократном проходе программы до команды ret.
Почему я здесь и задаю тупые вопросы?
Потому что хочу научиться.
Потому что хочу научиться.
Подстановку перенаправления выхода через подмену адреса возврата в верхушке стека что-ли содеять хочется?

Так учти особенности адресации памяти у АВРок - там не метка подставляться должна, а метка,смещенная на бит влево с младшим битом = 0.
и сам указатель стека скорректировать для переустановки надо:
для начала сделаем sp=sp+2 согласно имеющемуся МК (скоко там регистро - два или один - допустим POPами тоже можно "гасить")
затем грузим
ldi rn,low(metka*2)
push rn
ldi rn,high(metka*2)
push rn

Так учти особенности адресации памяти у АВРок - там не метка подставляться должна, а метка,смещенная на бит влево с младшим битом = 0.
и сам указатель стека скорректировать для переустановки надо:
для начала сделаем sp=sp+2 согласно имеющемуся МК (скоко там регистро - два или один - допустим POPами тоже можно "гасить")
затем грузим
ldi rn,low(metka*2)
push rn
ldi rn,high(metka*2)
push rn
Mika, все правильно, в итоге прога застрянет в cycle_2
Только единственное, как уже сказали, надо адреса флеша умножать на 2, прежде чем пихать в стек.
А вообще, таких трюков, конечно, лучше стараться избегать
Ну а для обучения полезно конечно, да 
Только единственное, как уже сказали, надо адреса флеша умножать на 2, прежде чем пихать в стек.
А вообще, таких трюков, конечно, лучше стараться избегать
Есть вопрос: с одного таймера в меге можно ли получить 2 независимых аппаратных канала ШИМ? Что-то ответа не нагуглил...
Прибор, защищённый предохранителем, сгорает первым, защитив предохранитель. Закон Мерфи.


