Помогите собрать Светофор

[аладин]

там в основном макеты и схемы на мк , но которые не на мк нет деталей типа ие16 и др и на лампах , а мне нужно на светодиодах. Вот вы привели классный вариант мяууу !!!!!!!:))

[аладин]

База VT3 туда ли подключена? Впрочем к делу это не имеет отношения.
По вашей схеме светодиоды будут переключаться друг за другом, по очереди, по разу. Для светофора не годится. Если уж всё упирается именно в эту схему, то надо делать так, чтобы сигнал с VT2 активировал еще одну такую схему, которая бы и моргала желтым. Но это такой изврат. Итого: смотрим на цифровые микросхемы, здесь пользуемся поиском.
Либо делаем на мк:

Спойлер

;
;Светофор
;
#include <p16f84.inc> ;подключаем файл определений мк

counter equ 0x0C ;счетчик для регулирования скорости переключения ламп
takt equ 0x0D ;текущий такт светофора
temp equ 0x0E ;временная переменная
temp1 equ 0x0F ;временная переменная

org 0 ;начальный адрес программы
clrf INTCON ;запрет всех прерываний
goto START ;переход на начало

org 04h ;вектор прерываний
goto interrupt ;переход на подпрограмму обработки прерываний
;
START
bsf STATUS, RP0 ;включаем BANK1
movlw b'11111000' ;RA0,RA1,RA2 - выходы
movwf TRISA ;запись в TRISA
movlw b'00000011' ;RB7..RB2 - выходы
movwf TRISB ;запись в TRISB
movlw b'00000100' ;определение прескалера для таймера 1:32
movwf OPTION_REG ;запись в OPTION_REG
bcf STATUS,RP0 ;включаем BANK0
clrw ;обнуляем рабочий регистр
movwf PORTA ;устанавливаем на выходах порта А нули(гасим лампы)
movwf PORTB ;устанавливаем на выходах порта B нули(гасим лампы)

movlw 0x3D ;начальное состояние счетчика
movwf counter ;в переменную
movlw .31 ;начальное количество тактов
movwf takt ;в переменную

movlw b'10100000' ;взводим биты нужных прерываний
movwf INTCON ;разрешаем прерывание от таймера и общее разрешение
loop
goto loop ;зацикливаемся на метке loop
;************************
;
;************************
interrupt
btfss INTCON,T0IF ;проверяем флаг прерывания от таймера
retfie ;если не таймер, то выходим из п/п

decfsz counter ;уменьшаем счетчик
goto m1 ;если он не "0", то выходим из п/п
movlw 0x3D ;начальное состояние счетчика
movwf counter ;в переменную
;
;
decfsz takt ;уменьшаем номер такта
goto m2 ;если не достиг "0", то переходим на m2
movlw .31 ;начальное количество тактов
movwf takt ;в переменную takt
m2
movf takt,w ;номер такта в регистр W
addlw 0xFF ;W= W - 1
call table ;выбираем нужное сочетание светящихся/потушенных ламп
;в W находится D7 D6 D5 D4 D3 D2 D1 D0
;пересылка в порт А обеспечивает установку цветов светофора_1.
;Биты 7..3 роли не играют
movwf temp ;сохраняем во временной переменной
movwf PORTA ;выводим на светофор_1

swapf temp ;обмен тетрад. В temp'е D3 D2 D1 D0 D7 D6 D5 D4
rlf temp ;сдвиг влево на один бит. В temp'е D2 D1 D0 D7 D6 D5 D4 Х

movf temp,w ;сохраняем в регистре W
rlf temp ;еще раз сдвигаем влево. В temp'е D1 D0 D7 D6 D5 D4 Х Х

andlw 0xE0 ;сбрасываем 4..0 биты. В W D2 D1 D0 0 0 0 0 0
movwf temp1 ;сохраняем W во временной переменной
movf temp,w ;пересылаем temp в регистр W
andlw 0x1C ;сбрасываем 7..5 и 1..0 биты. В W 0 0 0 D6 D5 D4 0 0
iorwf temp1 ;операция ИЛИ между temp1 и W. В temp1 D2 D1 D0 D6 D5 D4 0 0
movf temp1,w ;пересылаем в W
movwf PORTB ;заносим в порт В

m1
bcf INTCON,T0IF ;сбрасываем флаг прерывания от таймера
retfie ;выход из п/п обработки прерывания
;
;Подпрограмма возвращает данные для ламп
;Такты перебираются от 31-го до 1-го и далее, по кругу.
;
; b'D7 D6 D5 D4 D3 D2 D1 D0'
;
;D0 - красный светофора_1 и светофора_3
;D1 - желтый светофора_1 и светофора_3
;D2 - зеленый светофора_1 и светофора_3
;D3 - "0"
;D4 - красный светофора_2
;D5 - желтый светофора_2
;D6 - зеленый светофора_2
;D7 - "0"
;
table
addwf PCL,f ;в зависимости от номера такта делаем переход
retlw b'00110010' ;данные для такта 1
retlw b'00110010' ;данные для такта 2
retlw b'00110010' ;данные для такта 3
retlw b'00110010' ;данные для такта 4
retlw b'00110010' ;данные для такта 5
retlw b'00010100' ;данные для такта 6
retlw b'00010000' ;данные для такта 7
retlw b'00010100' ;данные для такта 8
retlw b'00010000' ;данные для такта 9
retlw b'00010100' ;данные для такта 10
retlw b'00010000' ;данные для такта 11
retlw b'00010100' ;данные для такта 12
retlw b'00010100' ;данные для такта 13
retlw b'00010100' ;данные для такта 14
retlw b'00010100' ;данные для такта 15
retlw b'00010100' ;данные для такта 16
retlw b'00100011' ;данные для такта 17
retlw b'00100011' ;данные для такта 18
retlw b'00100011' ;данные для такта 19
retlw b'00100011' ;данные для такта 20
retlw b'00100011' ;данные для такта 21
retlw b'01000001' ;данные для такта 22
retlw b'00000001' ;данные для такта 23
retlw b'01000001' ;данные для такта 24
retlw b'00000001' ;данные для такта 25
retlw b'01000001' ;данные для такта 26
retlw b'00000001' ;данные для такта 27
retlw b'01000001' ;данные для такта 28
retlw b'01000001' ;данные для такта 29
retlw b'01000001' ;данные для такта 30
retlw b'01000001' ;данные для такта 31

end ;конец программы

Приложение воспроизводить uvPlayer'ом.

это глюк все было правильно

[pyzhman]

Где глюк? Что было правильно?

[аладин]

на моей схеме трёхфазного мультивибратора

[sergeisams]

и на лампах , а мне нужно на светодиодах

Ну и какая проблема, вместо ламп через ключи подключить светодиоды ?

[аладин]

как это всё сделать .....

[sergeisams]

В выше приведенных схемах есть и светодиоды, и лампочки.
По аналогии их подключаешь к выходам микросхем.

[аладин]

а что если собрать таймер ,который будет работать так :зелёный горит ,5 - 6 секунд мигает ,затем переключение на желтый 2 - 3 секунды ,переключение на красный(такой же такт как и у зелёного )

[pyzhman]

Если собрать и наладить, то будет работать.

[аладин]

один вопрос - КАК

[pyzhman]

задвигаем аналог подальше - юзаем цифру, т.е. цифровые микросхемы.

[аладин]

я понял что вы имели но мне нужен переключатель ,вот такой :

[mamon]

Спойлер

http://radiowiki.ru/wiki/%D0%92%D0%B2%D0%B5%D0%B4%D0%B5%D0%BD%D0%B8%D0%B5_%D0%B2_%D1%86%D0%B8%D1%84%D1%80%D0%BE%D0%B2%D1%83%D1%8E_%D1%82%D0%B5%D1%85%D0%BD%D0%B8%D0%BA%D1%83/%D0%9C%D0%BE%D0%B4%D0%B5%D0%BB%D1%8C_%D1%81%D0%B2%D0%B5%D1%82%D0%BE%D1%84%D0%BE%D1%80%D0%B0

p.s. чтоб Зелёный мигал на одну ногу DD3.3 надо подать сигнал от другого генератора с частотой "по вкусу"

p.p.s. любимая схема

[Илья79]

Вот, много уже сделал светофоров для автодромов, и для обычного перекрестка будет работать.
Схема временных интервалов снята с рабочего перекрестка.
В схеме не реализован контроль красных и конфликт зеленых.
http://i-l-u-h-a.narod.ru/index_files/devais4/devais1.html

[s64]

делал внуку в дет.сад, интервалы уменьшены, потому как игрушка. Но исходники и схема прилагаются.( IAR, PCAD2006)

[_AHTOXA_]

Вот ещё светофор:)

[validol64]

В старых журналах Радио схема

[Alexey_Sh]

Пара светофоров:

Спойлер

[_and_]

подскажите пожалуйста схему для ручного последовательного переключения 3 лампового сфетофора одной кропкой.155 ие 7 пойдет?



Сюда перенес.
aen