?
Jack_A писал(а):...
концепция:
Смотрим в сторону ПЛК. Есть модуль процессора, панель оператора, расширение ввода-вывода. Эти блоки абсолютно самостоятельны. В модуле процессора крутится только программа цикла работы оборудования. Панель оператора вообще модуль с собственной операционной системой. Для панели оператора создается свой проект. И для вывода информации панель операторы опрашивает модуль процессора, тот выдает нужные данные. Набор данных зависит от состояния, в котором находится программа панели оператора. Скажем исходный режим - отображение одной информации, при входе в параметры отображается другая информация.
Именно такой подход я использую в последнее время в своих проектах. Только модули программные. Модуль аппаратной части дисплея. Модуль вывода информации. Модуль управления устройством, для которого текущий проект и создается. И этот подход полностью себя оправдал. Все модули абсолютно самостоятельны. Нет взаимосвязей. Легко отлаживать и проекты создаются в разы быстрее.
Если вы собираетесь использовать графический дисплей, тем более для станка, то для дисплея вам нужно создать отдельный проект, который будет получать значения переменных, рабочие данные. И в зависимости от состояния показывать нужную информацию. То есть, делать что-то вроде панели оператора.
Плюсы - проекты гораздо легче создавать и отлаживать. Разгружается "модуль процессора". Он теперь занят только циклом работы оборудования.
dr.doc писал(а):...
Demiurg писал(а):Shark-vc писал(а):...
У тебя либо инициализация хромает, либо аппаратная часть (непропай, замыкание, обрыв). Возможно просто нужно подкрутить контростность.
Я даю тебе архив с рабочей либой для ЖКИ. У меня 20х4, 4-битный интерфейс. Работает либа так: раз в 1 мс, посимвольно отправляется содержимое буфера на дисплей. В программе работаем с буфером. Но можно работать и напрямую с дисплеем. Разбирайся сам. Отвечу только на уточняющие вопросы.
Shark-vc писал(а):...
Demiurg писал(а):Попробуйте сделать простой опыт. Соберите макетку с минимумом. МК, кварц, дисплей. Забейте все знакоместа чем-нибудь. И оставьте все дело включенным на длительное время (несколько суток). Ессно, БП должен быть с хорошим качеством питания. И я вам гарантирую, через некоторое время работы на дисплее будут кракозябры. Кстати, дисплей можно не забивать данными. Достаточно проинициализировать его.
Demiurg писал(а):Shark-vc писал(а):...
AVR-Studio 4.19
Shark-vc писал(а):курсовая из-за него идет под каток :с
СКАЗОЧНИК писал(а):Shark-vc писал(а):курсовая из-за него идет под каток :с
А вот это вы зря сказали... Теперь точно никто не поможет. По крайней мере бесплатно. и в этой теме, которая про ассемблер, а не про дисплеи. И так уже срачу развели.
простите за оффтоп. Можно его удалить.
З.Ы. Не ставится АВР Студио 4.19, значит снесите свою винду 10 и поставьте винду 8... Вот и все решение проблемы.
Код: Выделить всё
.include "m8_ini_st.asm" ;ATmega8 + стек
;используемые переменные
.def dat_LCD = r17
.def temp = r16
;----------
.cseg ;данная директива означает, что дальше идет код программы
rcall ini_lcd ; Инициализация портов и ЛСД., и п/п записи команд и кода в ЛСД по 4-и шинам
; используемые порты D (D4...D7) и B (B0, B1)
; данные загружаем в "dat_LCD" он же - R17 и идем на ... "zap_dan" (rcall zap_dan)
; команды загружаем в "dat_LCD" он же - R17 и идем на "zap_com" (rcall zap_com)
;========== программа =========
; программа просмотра символов ЛСД
; от 0 до 255 - просматриваем знакогенератор ЛСД
m1: ldi r24,0x00
mov r0,r24 ; R0 - счетчик и hex код для преобразования
m2: ldi dat_lcd,0x83; устанавливаем курсор в 6-ю позицию
rcall zap_com ;
rcall pr_hex ; преобразование hex в ASCII
mov dat_lcd,pr_dat_h; выводим старшее значение hex кода
rcall zap_dan
mov dat_lcd,pr_dat_l; выводим младшее значение hex кода
rcall zap_dan
ldi dat_lcd,0x3d ; знак "="
rcall zap_dan
ldi dat_lcd,0x3e ; знак ">"
rcall zap_dan
mov dat_lcd,r0 ; сам hex код на выход
rcall zap_dan
ldi temp,255 ; задержка между выводим символов
rcall zad_b_
rcall zad_b_
rcall zad_b_
rcall zad_b_
inc r0 ; следующий знак
mov r24,r0
brne m2 ; тут можно поставить и "rjmp m2", ну чтобы флаги зря не проподали...
rjmp m1
.include "ini_LCD_4pin.asm"
.include "zad.asm"
.include "hex2ascii.asm"
Код: Выделить всё
.nolist ;данная директива отключает генерацию кода в листинг,
; т.е. далее в файле *.lss не будет фиксироваться
;ассемблерный код
.include "m8def.inc" ;подключение стандартного заголовочного файла для ATmega8
.list ;данная директива включает генерацию кода в листинг, т.е.
;далее в файле *.lss будет фиксироваться ассемблерный код
;УСТАНОВКА СТЕКА
ldi R16,low(RAMEND) ;скопируем в R16 младщий байт из константы RAMEND,
;которая определена в m8def.inc и хранит размер SRAM
out SPL,R16 ;скопируем значение из R16 в SPL
ldi R16,high(RAMEND) ;скопируем в R16 старший байт из константы RAMEND,
;которая определена в m8def.inc
out SPH,R16 ;скопируем значение из R17 в SPH
Код: Выделить всё
; Инициализация портов и ЛСД., и п/п записи команд и кода в ЛСД по 4-и шинам
; используемые порты D (D4...D7) и B (B0, B1)
;
;+++++++++ описалово ++++++++
;
; инициализация портов для ЛСД и самого ЛСД - точка входа: "ini_lcd"
;
; данные загружаем в "dat_LCD" он же - R17 и идем на ... "zap_dan" (rcall zap_dan)
; команды загружаем в "dat_LCD" он же - R17 и идем на "zap_com" (rcall zap_com)
;
;++++++++++++++++++++++++++++++
;----------
; обознач. на схеме выводы на mega8, на ЛСД
.set RS = 0 ;В0(14) <=> RS(4),
.set E = 1 ;B1(15) <=> E(6)
.set D4 = 4 ;D4(6) <=> D4(11)
.set D5 = 5 ;D5(11) <=> D5(12)
.set D6 = 6 ;D6(12) <=> D6(13)
.set D7 = 7 ;D7(13) <=> D7(14)
;.equ portB,1 = pinE
;.equ portB,0 = pinRS
;----------
;используемые регистры
.def dat_LCD = r17
.def temp = r16
ini_lcd:
; используемые порты D и B
; --- настройка портов
ldi temp,0xff
out ddrD,temp ; порт D на Выход
out ddrB,temp ; порт B на Выход
ldi temp,0x00
out portD,temp ; обнуляем порт D
out portB,temp ; обнуляем порт B
; --- инициализация ЛСД 4 шин
ldi temp,255 ; в данном случае - максимальная задержка
rcall zad_b_
rcall zad_b_ ;задержка после подачи питания
ldi dat_LCD,0x20 ; включить 4-и шинный обмен 1 строка (0x28 - 2 строки)
cbi portB,RS ; LCD - прием команд
rcall save1 ; запись
ldi dat_LCD,0x28 ; включить 4-и шинный обмен 2 строка (0x20 - 1 строки)
rcall zap_com
rcall zad_m
ldi dat_LCD,0x01 ; очистка памяти, курсор с лева
rcall zap_com
ldi temp,0xff ; большая задержка
rcall zad_b_
ldi dat_LCD,0x0e ; вид курсора
rcall zap_com
ldi dat_LCD,0x06 ; авто-сдвиг в право
rcall zap_com
ret
;----- запись команд в ЛСД -----8
zap_com:
cbi portB,RS ; LCD - прием команд
rjmp save
;----- запись данных в ЛСД -----
zap_dan:
sbi portB,RS ; LCD - прием данных
; -- процесс записи ----------
save:
push dat_LCD ; подготовка старшего полубайта (команды или данных):
andi dat_LCD,0xf0 ; очищаем младший полубайт
rcall save1 ; запись старшего полубайта (команды или данных)
pop dat_lcd
swap dat_LCD ; подготовка младшего полубайта (команды или данных)
andi dat_LCD,0xf0 ; очищаем младший полубайт
; запись младшего полубайта (команды или данных)
save1:
sbi portB,E ; подготовка строба
rcall zad15
out portD,dat_LCD ; вывод полубайта (команды или данных) на шины
rcall zad15
cbi portB,E ; строб записи полубайта (команды или данных)
rcall zad15
ret
Код: Выделить всё
;Преобразование hex кода в код для вывода на печать.
;
; П/П преобразования использует R24, R25
;
;(((((((((((((: ОПИСАЛОВО :))))))))))))))))
; - 1 -------
; Вход: для преобразования байта, оный заносим в r24 (pr_dat_l)
; точка входа "pr_hex"
;
; Выход: "pr_dat_h" = r25 - старший символ от входного (r24 (pr_dat_l)),
; pr_dat_l = r24 - младший символ
;
; - 2 ------
; Вход: для преобразования полубайта, оный заносим в r24 (pr_dat_l) младшие разряды (4-0)
; точка входа "pr_polu_bait"
;
; Выход: "pr_dat_l" = r24
;
;(((((((((((((((((((((((()))))))))))))))))))))))
;===============
;используемые переменные
.def pr_dat_h = r25
.def pr_dat_l = r24
pr_hex:
mov pr_dat_h,pr_dat_l ; запоминаем младший полубайт
swap pr_dat_l ; подготавливаем старший полубайт
rcall pr_polu_bait ; идем преабразовывать
push pr_dat_l ; запоминаем результат старшого полубайта
mov pr_dat_l,pr_dat_h ; младший полубайт на обработку
pop pr_dat_h ; старший результат в "pr_dat_h" R25
rcall pr_polu_bait
ret
pr_polu_bait:
andi pr_dat_l,0x0f ; очищаем старший полубайт
cpi pr_dat_l,0xa ; узнаем это цифра или буква (R24-9)
brcc bukvi ; флаг переноса очищен => R24>9 т.е буквы A,B,C,D,E,F
ori pr_dat_l,0x30 ; если цифра - добавляем в старший полубайт 30h чтоб
ret ;получить код ascii... код готов
bukvi: subi pr_dat_l,0x9 ; если буква - корректируем...
ori pr_dat_l,0x40 ; добавляем 40h. код готов.
ret
Код: Выделить всё
;---- задержка -----
;
;--------- описалово ----------
;
; используемые регистры R14,R15,R16
; R16 - он же "temp" - для загрузки констант, которые определяются самим писуном,
; в зависимости от частоты камняи и т.д...
; R14, R15 - счетные регистры - соответственно для малой и большой задержок
;
; ВХОДЫ - zad_m; zad_b - соответственно для малой и большой задержок - с
; записанными константами
; zad_m_; zad_b_ - соответственно для малой и большой задержок с привнесенной
; константой в R16 - он же "temp"
; ВЫХОД - зря потраченное время :)
;----------
;.org pp_zad
.def temp = r16
; ---- малая задержка ---
zad_m: ldi temp,255
zad_m_: mov r14,temp
l_zad_m: dec r14 ;R14-1
brne l_zad_m ;переход если R14 <> 0
ret
zad15: ldi temp,15
rjmp zad_m_
; ----множитель малой задержки ---
zad_b: ldi temp,123
l_zad_b: rcall zad_m
dec r15
brne l_zad_b
RET
zad_b_: mov r15,temp
l_zad_b1: rcall zad_m_
dec r15
brne l_zad_b1
RET
) места. Описать его в начале (либо в другом месте), а вливаться ему в программу по указанной метке. (Но это уже, наверное, из области макросов в коих я пока вообще никак.) А так хотелось - указал в начале (либо в другом месте) программы, что нулевой пин порта "B" - это здесь и далее по тексту обозначается как "pinRS", - то при замене на любой другой вывод, надо только переназначить "pinRS" и не гонятся по всему тексту за "portB,0". Код: Выделить всё
#define TEST B
#define _PORT(x) PORT##x
#define PORT(x) _PORT(x)
sbi PORT(TEST),0