Моя любимая тема.
Проворачивал косвенные вызовы на ассемблере AVR.
Нужно завести сначала массив указателей на вызываемые подпрограммы - обработчики состояний автомата.
Код: Выделить всё
;---------------------------------------------- Таблица переходов
STATES:
.dw STATE_0, STATE_1, STATE_2
STATE_0:
ldi temp0, 0x01 ;Переключаем на следующее состояние
ret
STATE_1:
ldi temp0, 0x02 ;Переключаем на следующее состояние
ret
STATE_2:
ldi temp0, 0x00 ;Переключаем на начальное состояние
ret
Далее сам автомат, который может вызываться в основном цикле.
Стоит заметить, что я не привожу тут загрузку и сохранение текущего состояния в ОЗУ.
Код: Выделить всё
; Много телодвижений связано с тем, что в конкретном МК LPM и IJMP или ICALL работают только с парой Z
; Сначала грузим номер текущего состояния из ОЗУ в регистры temp0 и temp1
; За тем выполняем код ниже:
ldi ZL, Low(STATES*2) ; Грузим начальный адрес массива указателей на процедуры
ldi ZH, High(STATES*2)
lsl temp0 ; В регистрах temp0 и temp1 хранится номер текущего состояния. temp0 - младший байт
clr temp1 ; , temp1 - старший. Но тут он не используется, так как состояний не так много было
add ZL, temp0 ;Смещаемся по массиву для выбора нужного указателя
adc ZH, temp1
lpm temp2, Z ; Грузим младший байт адреса
adiw Z, 0x01 ; Смещаемся к старшему байту адрса
lpm temp3, Z ; Грузим старший байт адреса
mov ZL, temp2 ; Заносим байты алреса процедуры в Z
mov ZH, temp3
icall ; Вызываем процедуру
; Тут можем сохранить номер состояния в ОЗУ
Разумеется, такой метод работает только для конечных автоматов, у которых номера состояний идут подряд.
Для декодирования команд лучше проверять на значение, например, пропуском следующей инструкции, если условие не выполняется, а в пропускаемой инструкции может содержаться переход на нужную процедуру, если условие выполняется.
Смысл в дополнительной таблице векторов? Лишний расход ПЗУ?
Пара инструкций сравнение + переход по условию занимают четыре байта. А если процедура далеко, то и все шесть. Ну и проход по простыне условий затрачивает лишние такты.
А вот один адрес в массиве занимает только два байта, что при большом количестве состояний нехило сэкономит ПЗУ и увеличит быстродействие. Быстродействие вообще почти мгновенное: Вычислил смещение, загрузил адрес, вызвал процедуру по этому адресу.
В жизни был проект, где был КА на 45 состояний (обработчик сложного протокола обмена) И там такой метод дал много выйгрыша.
Если у Вас всё получилось как задумано, то я очень рад что хоть чем-то смог помочь. 
